System Booster/System Booster.iso/Archives/GNU/GNUPLOTdoc.lha/docs/gnuplot.doc

Text File | 1996-01-30 | 174.2 KB | 4,679 lines

^ <h2> An Interactive Plotting Program </h2><p>
^ <h2>  Thomas Williams & Colin Kelley</h2><p>
^ <h2>   Version 3.6 organized by: David Denholm </h2><p>
^   Major contributors (alphabetic order):</h2>
^<ul><h3>
^<li>  John Campbell
^<li>  Robert Cunningham
^<li>  David Denholm
^<li>  Gershon Elber
^<li>  Roger Fearick
^<li>  Carsten Grammes
^<li>  Thomas Koenig
^<li>  David Kotz
^<li>  Ed Kubaitis
^<li>  Russell Lang
^<li>  Alexander Lehmann
^<li>  Carsten Steger
^<li>  Tom Tkacik
^<li>  Jos Van der Woude
^<li>  Alex Woo
^</h3></ul> <p>
^<h2>  Copyright (C) 1986 - 1995   Thomas Williams, Colin Kelley<p>
^   Mailing list for comments: [e-mail] <p>
^   Mailing list for bug reports: [e-mail]<p>
^</h2><p>
^<h3> This manual is for `gnuplot` version 3.6
^<li> prepared by: Dick Crawford </h3><p>
^<hr>
^<address> <a href="http://playfair.stanford.edu/~woo/woo.html">Alex Woo, [e-mail] </a></address>
1 gnuplot
?
 `gnuplot` is a command-driven interactive function and data plotting program.

 For help on any topic, type `help` followed by the name of the topic.  If the
 precise name of the topic is not known, type `help` and a menu will be given.
 Typing a question mark `?` after any `help` prompt will cause the menu to be
 listed again.

 The new `gnuplot` user should begin by reading the `introduction` topic (see
 `help introduction`) and the `plot` topic (see `help plot`).  Additional help
 can be obtained from the USENET newsgroup comp.graphics.apps.gnuplot.

2 copyright
?copyright
      Copyright (C) 1986 - 1993   Thomas Williams, Colin Kelley

 Permission to use, copy, and distribute this software and its documentation
 for any purpose with or without fee is hereby granted, provided that the
 above copyright notice appears in all copies and that both that copyright
 notice and this permission notice appear in supporting documentation.

 Permission to modify the software is granted, but not the right to distribute
 the modified code.  Modifications are to be distributed as patches to the
 released version.

 This software is provided "as is" without express or implied warranty.


   AUTHORS

     Original Software:
       Thomas Williams,  Colin Kelley.

     Gnuplot 2.0 additions:
         Russell Lang, Dave Kotz, John Campbell.

     Gnuplot 3.0 additions:
         Gershon Elber and many others.

2 seeking-assistance
?seeking-assistance
 There is a mailing list for `gnuplot` users.  Note, however, that the
 newsgroup
         comp.graphics.apps.gnuplot
 is identical to the mailing list (they both carry the same set of messages).
 We prefer that you read the messages through the newsgroup rather than
 subscribing to the mailing list.  Administrative requests should be sent to
    [e-mail]
 Send a message with the body (not the subject) consisting of the single word
 "help" (without the quotes) for more details.

 The address for mailing to list members is:
   [e-mail]

 Bug reports and code contributions should be mailed to:
   [e-mail]

 The list of those interested in beta-test versions is:
   [e-mail]

 There is also a World Wide Web page with up-to-date information, including
 known bugs:
    http://www.cs.dartmouth.edu/gnuplot

 Before seeking help, please check the FAQ (Frequently Asked Questions) list.
 If you do not have a copy of the FAQ, you may request a copy by email from
 the Majordomo address above, or see the WWW `gnuplot` page.

 When posting a question, please include full details of the version of
 `gnuplot`, the machine, and operating system you are using.  A _small_ script
 demonstrating the problem may be useful.  Function plots are preferable to
 datafile plots.  If email-ing to info-gnuplot, please state whether or not
 you are subscribed to the list, so that users who use news will know to email
 a reply to you.  There is a form for such postings on the WWW site.
2 introduction
?introduction
 `gnuplot` is a command-driven interactive function plotting program.  It is
 case sensitive (commands and function names written in lowercase are not the
 same as those written in CAPS).  All command names may be abbreviated, as
 long as the abbreviation is not ambiguous.  Any number of commands may appear
 on a line, separated by semicolons (;).  Strings are indicated with quotes.
 They may be either single or double quotation marks, e.g.,

          load "filename"
          cd 'dir'

 although there are some subtle differences (see `syntax` for more details).

 Any command-line arguments are assumed to be names of files containing
 `gnuplot` commands, with the exception of standard X11 arguments, which are
 processed first.  Each file is loaded with the `load` command, in the order
 specified.  `gnuplot` exits after the last file is processed.  When no load
 files are named, `gnuplot` enters into an interactive mode.

 Commands may extend over several input lines by ending each line but the last
 with a backslash (\).  The backslash must be the LAST character on each line.
 The effect is as if the backslash and newline were not there.  That is, no
 white space is implied, nor is a comment terminated.  Therefore, commenting
 out a continued line comments out the entire command (see `comment`).

 In this documentation, curly braces ({}) denote optional arguments and a
 vertical bar (|) separates mutually exclusive choices.  `gnuplot` keywords
 or help topics are indicated by backquotes or `boldface` (where available).
 Angle brackets (<>) are used to mark replaceable tokens.

 For help on any topic, type `help` followed by the name of the topic or just
 `help` to get a menu of available topics.

 The new `gnuplot` user should begin by reading about the `plot` command (type
 `help plot`).
^ <a href=simple/simple.html> Simple Plots Demo </a>
2 cd
?cd
 The `cd` command changes the working directory.

 Syntax:
         cd '<directory-name>'

 The directory name must be enclosed in quotes.

 Examples:
         cd 'subdir'
         cd ".."

 DOS users _must_ use single-quotes---backslash [\] has special significance
 inside double-quotes.  For example,

         cd "c:\newdata"      fails, but
         cd 'c:\newdata'      works as expected.
2 call
?call
 The `call` command is identical to the load command with one exception: you
 can have up to ten additional parameters to the command (delimited according
 to the standard parser rules) which can be substituted into the lines read
 from the file.  As each line is read from the `call`ed input file, it is
 scanned for the sequence `$` (dollar-sign) followed by a digit (0--9).  If
 found, the sequence is replaced by the corresponding parameter from the
 `call` command line.  If the parameter was specified as a string in the
 `call` line, it is substituted without its enclosing quotes.  `$` followed by
 any character other than a digit will be that character.  E.g. use `$$` to
 get a single `$`.  Providing more than ten parameters on the `call` command
 line will cause an error.  A parameter that was not provided substitutes as
 nothing.  Files being `call`ed may themselves contain `call` or `load`
 commands.

 The `call` command MUST be the last command on a multi-command line.

 Syntax:
         call "<input-file>" <parameter-0> <parm-1> ... <parm-9>

 The name of the input file must be enclosed in quotes, and it is recommended
 that parameters are similarly enclosed in quotes.

 Example:

 If the file 'calltest.gp' contains the line:

     pause 0 "p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"

 entering the command:

     call 'calltest.gp' "abcd" 1.2 + "'quoted'" -- "$2"

 will display:

     p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx

 NOTE: there is a clash in syntax with the datafile `using` callback
 operator.  Use $$n to access column n from a datafile inside a `call`ed
 datafile plot.
2 clear
?clear
 The `clear` command erases the current screen or output device as specified
 by `set output`.  This usually generates a formfeed on hardcopy devices.  Use
 `set terminal` to set the device type.
2 command-line-editing
?line-editing
?editing
?history
?command-line-editing
 Command-line editing is supported by the Unix, Atari, VMS, MS-DOS and OS/2
 versions of `gnuplot`.  Also, a history mechanism allows previous commands to
 be edited and re-executed.  After the command line has been edited, a newline
 or carriage return will enter the entire line without regard to where the
 cursor is positioned.

 The editing commands are as follows:

@start table - first is interactive cleartext form
  `Line-editing`:

  ^B moves back a single character.
  ^F moves forward a single character.
  ^A moves to the beginning of the line.
  ^E moves to the end of the line.
  ^H and DEL delete the previous character.
  ^D deletes the current character.
  ^K deletes from current position to the end of line.
  ^L,^R redraws line in case it gets trashed.
  ^U deletes the entire line.
  ^W deletes the last word.

  `History`:

  ^P moves back through history.
  ^N moves forward through history.
#Character && Function \\ \hline
#\multicolumn{3}{|c|}{Line Editing}\\
#\verb~^B~ && move back a single character.\\
#\verb~^F~ && move forward a single character.\\
#\verb~^A~ && move to the beginning of the line.\\
#\verb~^E~ && move to the end of the line.\\
#\verb~^H, DEL~ && delete the previous character.\\
#\verb~^D~ && delete the current character.\\
#\verb~^K~ && delete from current position to the end of line.\\
#\verb~^L, ^R~ && redraw line in case it gets trashed.\\
#\verb~^U~ && delete the entire line. \\
#\verb~^W~ && delete from the current word to the end of line. \\ \hline
#\multicolumn{3}{|c|}{History} \\
#\verb~^P~ && move back through history.\\
#\verb~^N~ && move forward through history.\\
%Character@@Function
%_
%@@Line Editing
%^B@@move back a single character.
%^F@@move forward a single character.
%^A@@move to the beginning of the line.
%^E@@move to the end of the line.
%^H, DEL@@delete the previous character.
%^D@@delete the current character.
%^K@@delete from current position to the end of line.
%^L, ^R@@redraw line in case it gets trashed.
%^U@@delete the entire line.
%^W@@delete from the current word to the end of line.
%_
%@@History
%^P@@move back through history.
%^N@@move forward through history.
@end table

 On the IBM PC, the use of a TSR program such as DOSEDIT or CED may be desired
 for line editing.  The default makefile assumes that this is the case;  by
 default `gnuplot` will be compiled with no line-editing capability.  If you
 want to use `gnuplot`'s line editing, set READLINE in the makefile and add
 readline.obj to the link file.  The following arrow keys may be used on the
 IBM PC and Atari versions if readline is used:

@start table - first is interactive cleartext form
  Left  Arrow      - same as ^B.
  Right Arrow      - same as ^F.
  Ctrl Left  Arrow - same as ^A.
  Ctrl Right Arrow - same as ^E.
  Up    Arrow      - same as ^P.
  Down  Arrow      - same as ^N.
#Arrow key  & Function & \\ \hline
#Left       & same as \verb~^B~. & \\
#Right      & same as \verb~^F~. & \\
#Ctrl Left  & same as \verb~^A~. & \\
#Ctrl Right & same as \verb~^E~. & \\
#Up         & same as \verb~^P~. & \\
#Down       & same as \verb~^N~. & \\
%Arrow key@@Function
%_
%Left Arrow@@same as ^B.
%Right Arrow@@same as ^F.
%Ctrl Left Arrow@@same as ^A.
%Ctrl Right Arrow@@same as ^E.
%Up Arrow@@same as ^P.
%Down Arrow@@same as ^N.
%_
@end table

 The Atari version of readline defines some additional key aliases:

@start table - first is interactive cleartext form
  Undo            - same as ^L.
  Home            - same as ^A.
  Ctrl Home       - same as ^E.
  Esc             - same as ^U.
  Help            - `help' plus return.
  Ctrl Help       - `help '.
#Arrow key & Function & \\ \hline
#Undo      & same as \verb~^L~. & \\
#Home      & same as \verb~^A~. & \\
#Ctrl Home & same as \verb~^E~. & \\
#Esc       & same as \verb~^U~. & \\
#Help      & `{\bf help}' plus return. & \\
#Ctrl Help & `{\bf help }'. & \\
%Arrow key@@Function
%_
%Undo@@same as ^L.
%Home@@same as ^A.
%Ctrl Home@@same as ^E.
%Esc@@same as ^U.
%Help@@help plus return.
%Ctrl Help@@help .
%_
@end table

 (The readline function in `gnuplot` is not the same as the readline used in
 GNU Bash and GNU Emacs.  It is somewhat compatible, however.)
2 comment
?comments
 Comments are supported as follows: a # may appear in most places in a line
 and `gnuplot` will ignore the rest of the line.  It will not have this effect
 inside quotes, inside numbers (including complex numbers), inside command
 substitutions, etc.  In short, it works anywhere it makes sense to work.
2 environment
?environment
 A number of shell environment variables are understood by `gnuplot`.  None of
 these are required, but may be useful.

 If GNUTERM is defined, it is used as the name of the terminal type to be
 used.  This overrides any terminal type sensed by `gnuplot` on start-up, but
 is itself overridden by the .gnuplot (or equivalent) start-up file (see
 `start-up`) and, of course, by later explicit changes.

 On Unix, AmigaDOS, AtariTOS, MS-DOS and OS/2, GNUHELP may be defined to be
 the pathname of the HELP file (gnuplot.gih).

 On VMS, the logical name gnuplot$HELP should be defined as the name of the
 help library for `gnuplot`.  The `gnuplot` help can be put inside any system
 help library, allowing access to help from both within and outside `gnuplot`
 if desired.

 On Unix, HOME is used as the name of a directory to search for a .gnuplot
 file if none is found in the current directory.  On AmigaDOS, AtariTOS,
 MS-DOS and OS/2, `gnuplot` is used.  On VMS, SYS$LOGIN: is used. See `help
 start-up`.

 On Unix, PAGER is used as an output filter for help messages.

 On Unix, AtariTOS and AmigaDOS, SHELL is used for the `shell` command.  On
 MS-DOS and OS/2, COMSPEC is used for the `shell` command.

 On MS-DOS, if the BGI interface is used, the variable `BGI` is used to point
 to the full path of the BGI drivers directory.  Furthermore, SVGA is used to
 name the Super VGA BGI driver in 800x600 resolution and its mode of operation
 as 'Name.Mode'.  E.g., if the Super VGA driver is C:\TC\BGI\SVGADRV.BGI and
 mode 3 is used for 800x600 resolution, then use 'set BGI=C:\TC\BGI' and 'set
 SVGA=SVGADRV.3'.

 FIT_SCRIPT may be used to specify a `gnuplot` command to be executed when a
 fit is interrupted---see `fit`.  FIT_LOG specifies the filename of the
 logfile maintained by fit.
2 exit
?exit
?quit
 The commands `exit` and `quit` and the END-OF-FILE character will exit
 `gnuplot`.  Each of these commands will clear the output device (as does
 the `clear` command) before exiting.
2 expressions
?expressions
 In general, any mathematical expression accepted by C, FORTRAN, Pascal, or
 BASIC is valid.  The precedence of these operators is determined by the
 specifications of the C programming language.  White space (spaces and tabs)
 is ignored inside expressions.

 Complex constants are expressed as {<real>,<imag>}, where <real> and <imag>
 must be numerical constants.  For example, {3,2} represents 3 + 2i; {0,1}
 represents `i` itself.  The curly braces are explicitly required here.

 Note that gnuplot uses both "real" and "integer" arithmetic, like FORTRAN and
 C.  Integers are entered as "1", "-10", etc; reals as "1.0", "-10.0", "1e1",
 3.5e-1, etc.  The most important difference between the two forms is in
 division: division of integers truncates: 5/2 = 1; division of reals does
 not: 5.0/2.0 = 2.5.  In mixed expressions, integers are "promoted" to reals
 before evaluation: 5/2e1 = 2.5.  The result of division of a negative integer
 by a positive one may vary among compilers.  Try a test like "print -5/2" to
 determine if your system chooses -2 or -3 as the answer.

 The real and imaginary parts of complex expressions are always real, whatever
 the form in which they are entered: in {3,2} the "3" and "2" are reals, not
 integers.
3 functions
?expressions functions
?functions
 The functions in `gnuplot` are the same as the corresponding functions in
 the Unix math library, except that all functions accept integer, real, and
 complex arguments, unless otherwise noted.  The `sgn` function is also
 supported, as in BASIC.
@start table
#Function & Arguments & Returns \\ \hline
%Function@Arguments@Returns
%_
4 abs
?expressions functions abs
?functions abs
?abs
#abs(x) & any  &  absolute value of {\tt x}, $|x|$; same type \\
#abs(x) & complex &  length of {\tt x}, $\sqrt{{\mbox{real}(x)^{2} +
#\mbox{imag}(x)^{2}}}$ \\
%abs(x)@any@absolute value of x, $|x|$; same type
%abs(x)@complex@length of x, $sqrt{roman real (x) sup 2 + roman imag (x) sup 2}$
 The `abs` function returns the absolute value of its argument.  The returned
 value is of the same type as the argument.

 For complex arguments, abs(x) is defined as the length of x in the complex
 plane [i.e.,  sqrt(real(x)**2 + imag(x)**2) ].
4 acos
?expressions functions acos
?functions acos
?acos
#acos(x) & any  & $\cos^{-1} x$ (inverse cosine) in radians \\
%acos(x)@any@$cos sup -1 x$ (inverse cosine) in radians
 The `acos` function returns the arc cosine (inverse cosine) of its argument.
 `acos` returns its argument in radians.
4 arg
?expressions functions arg
?functions arg
?arg
#arg(x) & complex & the phase of $x$ in radians\\
%arg(x)@complex@the phase of $x$ in radians
 The `arg` function returns the phase of a complex number, in radians.
4 asin
?expressions functions asin
?functions asin
?asin
#asin(x) & any  & $\sin^{-1} x$ (inverse sin) in radians \\
%asin(x)@any@$sin sup -1 x$ (inverse sin) in radians
 The `asin` function returns the arc sin (inverse sin) of its argument.
 `asin` returns its argument in radians.
4 atan
?expressions functions atan
?functions atan
?atan
#atan(x) & any  & $\tan^{-1} x$ (inverse tangent) in radians \\
%atan(x)@any@$tan sup -1 x$ (inverse tangent) in radians
 The `atan` function returns the arc tangent (inverse tangent) of its
 argument.  `atan` returns its argument in radians.
4 besj0
?expressions functions besj0
?functions besj0
?besj0
#besj0(x) & radians &  $j_{0}$ Bessel function of $x$ \\
%besj0(x)@radians@$j sub 0$ Bessel function of $x$
 The `besj0` function returns the j0th Bessel function of its argument.
 `besj0` expects its argument to be in radians.
4 besj1
?expressions functions besj1
?functions besj1
?besj1
#besj1(x) & radians & $j_{1}$ Bessel function of $x$ \\
%besj1(x)@radians@$j sub 1$ Bessel function of $x$
 The `besj1` function returns the j1st Bessel function of its argument.
 `besj1` expects its argument to be in radians.
4 besy0
?expressions functions besy0
?functions besy0
?besy0
#besy0(x) & radians & $y_{0}$ Bessel function of $x$ \\
%besy0(x)@radians@$y sub 0$ Bessel function of $x$
 The `besy0` function returns the y0th Bessel function of its argument.
 `besy0` expects its argument to be in radians.
4 besy1
?expressions functions besy1
?functions besy1
?besy1
#besy1(x) & radians & $y_{1}$ Bessel function of $x$ \\
%besy1(x)@radians@$y sub 1$ Bessel function of $x$
 The `besy1` function returns the y1st Bessel function of its argument.
 `besy1` expects its argument to be in radians.
4 ceil
?expressions functions ceil
?functions ceil
?ceil
#ceil(x) & any & $\lceil x \rceil$, smallest integer not less than $x$
#(real part) \\
%ceil(x)@any@$left ceiling x right ceiling$, smallest integer not less than $x$ (real part)
 The `ceil` function returns the smallest integer that is not less than its
 argument.  For complex numbers, `ceil` returns the smallest integer not less
 than the real part of its argument.
4 column
?expressions functions column
?functions column
?column
#column(x) & int & column $x$ during datafile manipulation. \\
%column(x)@int@ & column $x$ during datafile manipulation.
 `column(x)` may be used only in expressions as part of `using` manipulations
 to fits or datafile plots.  See `plot datafile using`.
4 cos
?expressions functions cos
?functions cos
?cos
#cos(x) & radians & $\cos x$, cosine of $x$ \\
%cos(x)@radians@$cos~x$, cosine of $x$
 The `cos` function returns the cosine of its argument.  `cos` expects its
 argument to be in radians.
4 cosh
?expressions functions cosh
?functions cosh
?cosh
#cosh(x) & radians & $\cosh x$, hyperbolic cosine of $x$ \\
%cosh(x)@radians@$cosh~x$, hyperbolic cosine of $x$
 The `cosh` function returns the hyperbolic cosine of its argument.  `cosh`
 expects its argument to be in radians.
4 erf
?expressions functions erf
?functions erf
?erf
#erf(x) & any & $\mbox{Erf}(\mbox{real}(x))$,  error function of real($x$) \\
%erf(x)@any@$erf ( roman real (x))$, error function of real ($x$)
 The `erf` function returns the error function of the real part of its
 argument.  If the argument is a complex value, the imaginary component is
 ignored.
4 erfc
?expressions functions erfc
?functions erfc
?erfc
#erfc(x) & any & $\mbox{Erfc}(\mbox{real}(x))$,  1.0 - error function of real($x$) \\
%erfc(x)@any@$erfc ( roman real (x))$, 1.0 - error function of real ($x$)
 The `erfc` function returns 1.0 - the error function of the real part of its
 argument.  If the argument is a complex value, the imaginary component is
 ignored.
4 exp
?expressions functions exp
?functions exp
?exp
#exp(x) & any & $e^{x}$,  exponential function of $x$ \\
%exp(x)@any@$e sup x$, exponential function of $x$
 The `exp` function returns the exponential function of its argument (`e`
 raised to the power of its argument).  On some implementations (notably
 suns), exp(-x) returns undefined for very large x.  A user-defined function
 like safe(x) = x<-100 ? 0 : exp(x) might prove useful in these cases.
4 floor
?expressions functions floor
?functions floor
?floor
#floor(x) & any & $\lfloor x \rfloor$,  largest integer not greater
#than $x$ (real part) \\
%floor(x)@any@$left floor x right floor$, largest integer not greater than $x$ (real part)
 The `floor` function returns the largest integer not greater than its
 argument.  For complex numbers, `floor` returns the largest integer not
 greater than the real part of its argument.
4 gamma
?expressions functions gamma
?functions gamma
?gamma
#gamma(x) & any & $\mbox{Gamma}(\mbox{real}(x))$,  gamma function of real($x$) \\
%gamma(x)@any@$GAMMA ( roman real (x))$, gamma function of real ($x$)
 The `gamma` function returns the gamma function of the real part of its
 argument.  For integer n, gamma(n+1) = n!.  If the argument is a complex
 value, the imaginary component is ignored.
4 ibeta
?expressions functions ibeta
?functions ibeta
?ibeta
#ibeta(p,q,x) & any & $\mbox{Ibeta}(\mbox{real}(p,q,x))$,  ibeta function of real($p$,$q$,$x$) \\
%ibeta(p,q,x)@any@$Ibeta ( roman real (p,q,x))$, ibeta function of real ($p$,$q$,$x$)
 The `ibeta` function returns the incomplete beta function of the real parts
 of its arguments. p, q > 0 and x in [0:1].  If the arguments are complex,
 the imaginary components are ignored.
4 inverf
?expressions functions inverf
?functions inverf
?inverf
#inverf(x) & any &  inverse error function of real($x$)  \\
%inverf(x)@any@inverse error function real($x$)
 The `inverf` function returns the inverse error function of the real part
 of its argument.
4 igamma
?expressions functions igamma
?functions igamma
?igamma
#igamma(a,x) & any & $\mbox{Igamma}(\mbox{real}(a,x))$,  igamma function of real($a$,$x$) \\
%igamma(a,x)@any@$Igamma ( roman real (a,x))$, igamma function of real ($a$,$x$)
 The `igamma` function returns the incomplete gamma function of the real
 parts of its arguments.  a > 0 and x >= 0.  If the arguments are complex,
 the imaginary components are ignored.
4 imag
?expressions functions imag
?functions imag
?imag
#imag(x) & complex &  imaginary part of $x$ as a real number \\
%imag(x)@complex@imaginary part of $x$ as a real number
 The `imag` function returns the imaginary part of its argument as a real
 number.
4 invnorm
?expressions functions invnorm
?functions invnorm
?invnorm
#invnorm(x) & any &  inverse normal distribution function of real($x$)  \\
%invnorm(x)@any@inverse normal distribution function real($x$)
 The `invnorm` function returns the inverse normal distribution function of
 the real part of its argument.
4 int
?expressions functions int
?functions int
?int
#int(x) & real &  integer part of $x$, truncated toward zero \\
%int(x)@real@integer part of $x,$ truncated toward zero
 The `int` function returns the integer part of its argument, truncated
 toward zero.
4 lgamma
?expressions functions lgamma
?functions lgamma
?lgamma
#lgamma(x) & any & $\mbox{Lgamma}(\mbox{real}(x))$,  lgamma function of real($x$) \\
%lgamma(x)@any@$Lgamma ( roman real (x))$, lgamma function of real ($x$)
 The `lgamma` function returns the natural logarithm of the gamma function
 of the real part of its argument.  If the argument is a complex value, the
 imaginary component is ignored.
4 log
?expressions functions log
?functions log
?log
#log(x) & any & $\log_{e} x$,  natural logarithm (base $e$) of $x$ \\
%log(x)@any@$ln~x$, natural logarithm (base $e$) of $x$
 The `log` function returns the natural logarithm (base `e`) of its argument.
4 log10
?expressions functions log10
?functions log10
?log10
#log10(x) & any & $\log_{10} x$,  logarithm (base $10$) of $x$ \\
%log10(x)@any@${log sub 10}~x$, logarithm (base $10$) of $x$
 The `log10` function returns the logarithm (base 10) of its argument.
4 norm
?expressions functions norm
?functions norm
?norm
#norm(x) & any & normal distribution (Gaussian) function of real($x$) \\
%norm(x)@any@$norm(x),$ normal distribution function of real($x$)
 The `norm` function returns the normal distribution function (or Gaussian)
 of the real part of its argument.
4 rand
?expressions functions rand
?functions rand
?rand
#rand(x) & any & $\mbox{Rand}(\mbox{real}(x))$,  pseudo random number generator \\
%rand(x)@any@$rand ( roman real (x))$, pseudo random number generator
 The `rand` function returns a pseudo random number in the interval [0:1]
 using the real part of its argument as a seed.  If seed < 0, the sequence
 is (re)initialized.  If the argument is a complex value, the imaginary
 component is ignored.
4 real
?expressions functions real
?functions real
?real
#real(x) & any &  real part of $x$ \\
%real(x)@any@real part of $x$
 The `real` function returns the real part of its argument.
4 sgn
?expressions functions sgn
?functions sgn
?sgn
#sgn(x) & any & 1 if $x>0$, -1 if $x<0$, 0 if $x=0$. imag($x$) ignored \\
%sgn(x)@any@1 if $x > 0$, -1 if $x < 0$, 0 if $x = 0$. $roman imag (x)$ ignored
 The `sgn` function returns 1 if its argument is positive, -1 if its argument
 is negative, and 0 if its argument is 0.  If the argument is a complex value,
 the imaginary component is ignored.
4 sin
?expressions functions sin
?functions sin
?sin
#sin(x) & radians & $\sin x$, sine of $x$ \\
%sin(x)@radians@$sin~x$, sine of $x$
 The `sin` function returns the sine of its argument.  `sin` expects its
 argument to be in radians.
4 sinh
?expressions functions sinh
?functions sinh
?sinh
#sinh(x) & radians & $\sinh x$, hyperbolic sine $x$ \\
%sinh(x)@radians@$sinh~x$, hyperbolic sine $x$
 The `sinh` function returns the hyperbolic sine of its argument.  `sinh`
 expects its argument to be in radians.
4 sqrt
?expressions functions sqrt
?functions sqrt
?sqrt
#sqrt(x) & any & $\sqrt{x}$,  square root of $x$ \\
%sqrt(x)@any@$sqrt x $, square root of $x$
 The `sqrt` function returns the square root of its argument.
4 tan
?expressions functions tan
?functions tan
?tan
#tan(x) & radians & $\tan x$,  tangent of $x$ \\
%tan(x)@radians@$tan~x$, tangent of $x$
 The `tan` function returns the tangent of its argument.  `tan` expects
 its argument to be in radians.
4 tanh
?expressions functions tanh
?functions tanh
?tanh
#tanh(x) & radians & $\tanh x$, hyperbolic tangent of $x$\\
%tanh(x)@radians@$tanh~x$, hyperbolic tangent of $x$
 The `tanh` function returns the hyperbolic tangent of its argument.  `tanh`
 expects its argument to be in radians.
4 valid
?expressions functions valid
?functions valid
?valid
#valid(x) & int & test validity of $\mbox{column}(x)$ during datafile manip.\\
%valid(x)@int@ & test validity of column($x$) during datafile manip.
 `valid(x)` may be used only in expressions as part of `using` manipulations
 to fits or datafile plots.  See `plot datafile using`.
@end table
^ <a href=airfoil/airfoil.html>Use of functions and complex variables for airfoils </a>
3 operators
?expressions operators
?operators
 The operators in `gnuplot` are the same as the corresponding operators in the
 C programming language, except that all operators accept integer, real, and
 complex arguments, unless otherwise noted.  The ** operator (exponentiation)
 is supported, as in FORTRAN.

 Parentheses may be used to change order of evaluation.
4 unary
?expressions operators unary
?operators unary
?unary
 The following is a list of all the unary operators and their usages:

@start table - first is interactive cleartext form
  Symbol     Example      Explanation
   -           -a          unary minus
   +           +a          unary plus (no-operation)
   ~           ~a        * one's complement
   !           !a        * logical negation
   !           a!        * factorial
   $           $3        * call arg/column during `using` manipulation
#\multicolumn{3}{|c|}{Unary Operators}\\
#Symbol & Example & Explanation \\ \hline
#\verb@-@ & \verb@-a@ & unary minus \\
#\verb@+@ & \verb@+a@ & unary plus (no-operation) \\
#\verb@~@ & \verb@~a@ & * one's complement \\
#\verb@!@ & \verb@!a@ & * logical negation \\
#\verb@!@ & \verb@a!@ & * factorial \\
#\verb@$@ & \verb@$3@ & * call arg/column during `using` manipulation \\
%-@-a@unary minus
%+@+a@unary plus (no-operation)
%~@~a@* one's complement
%!@!a@* logical negation
%!@a!@* factorial
%$@$3@* call arg/column during `using` manipulation
@end table
 (*) Starred explanations indicate that the operator requires an integer
 argument.

 The factorial operator returns a real number to allow a greater range.
4 binary
?expressions operators binary
?operators binary
?binary
 The following is a list of all the binary operators and their usages:

@start table - first is interactive cleartext form
  Symbol      Example      Explanation
   **          a**b          exponentiation
   *           a*b           multiplication
   /           a/b           division
   %           a%b         * modulo
   +           a+b           addition
   -           a-b           subtraction
   ==          a==b          equality
   !=          a!=b          inequality
   <           a<b           less than
   <=          a<=b          less than or equal to
   >           a>b           greater than
   >=          a>=b          greater than or equal to
   &           a&b         * bitwise AND
   ^           a^b         * bitwise exclusive OR
   |           a|b         * bitwise inclusive OR
   &&          a&&b        * logical AND
   ||          a||b        * logical OR
#\multicolumn{3}{|c|}{Binary Operators} \\
#Symbol & Example & Explanation \\ \hline
#\verb~**~ & \verb~a**b~ & exponentiation\\
#\verb~*~ & \verb~a*b~ & multiplication\\
#\verb~/~ & \verb~a/b~ & division\\
#\verb~%~ & \verb~a%b~ & * modulo\\
#\verb~+~ & \verb~a+b~ & addition\\
#\verb~-~ & \verb~a-b~ & subtraction\\
#\verb~==~ & \verb~a==b~ & equality\\
#\verb~!=~ & \verb~a!=b~ & inequality\\
#\verb~<~ & \verb~a<b~ & less than\\
#\verb~<=~ & \verb~a<=b~ & less than or equal to\\
#\verb~>~ & \verb~a>b~ & greater than\\
#\verb~>=~ & \verb~a>=b~ & greater than or equal to\\
#\verb~&~ & \verb~a&b~ & * bitwise AND\\
#\verb~^~ & \verb~a^b~ & * bitwise exclusive OR\\
#\verb~|~ & \verb~a|b~ & * bitwise inclusive OR\\
#\verb~&&~ & \verb~a&&b~ & * logical AND\\
#\verb~||~ & \verb~a||b~ & * logical OR\\
%Symbol@Example@Explanation
%_
%**@a**b@exponentiation
%*@a*b@multiplication
%/@a/b@division
%%@a%b@* modulo
%+@a+b@addition
%-@a-b@subtraction
%==@a==b@equality
%!=@a!=b@inequality
%&@a&b@* bitwise AND
%^@a^b@* bitwise exclusive OR
%|@a|b@* bitwise inclusive OR
%&&@a&&b@* logical AND
%||@a||b@* logical OR

@end table
 (*) Starred explanations indicate that the operator requires integer
 arguments.

 Logical AND (&&) and OR (||) short-circuit the way they do in C.  That is,
 the second && operand is not evaluated if the first is false; the second ||
 operand is not evaluated if the first is true.
4 ternary
?expressions operators ternary
?operators ternary
?ternary
 There is a single ternary operator:

@start table - first is interactive cleartext form
  Symbol      Example      Explanation
   ?:          a?b:c       ternary operation
#\multicolumn{3}{|c|}{Ternary Operator} \\
#Symbol & Example & Explanation \\ \hline
#\verb~?:~ & \verb~a?b:c~ & ternary operation\\
%Symbol@Example@Explanation
%_
%?:@a?b:c@* ternary operation

@end table
 The ternary operator behaves as it does in C.  The first argument (a), which
 must be an integer, is evaluated.  If it is true (non-zero), the second
 argument (b) is evaluated and returned; otherwise the third argument (c) is
 evaluated and returned.

 The ternary operator is very useful both in constructing piecewise functions
 and in plotting points only when certain conditions are met.

 Examples:

 Plot a function that is to equal sin(x) for 0 <= x < 1, 1/x for 1 <= x < 2,
 and undefined elsewhere:

        f(x) = 0<=x & x<1 ? sin(x) : 1<=x & x<2 ? 1/x : 1/0
        plot f(x)

 Note that `gnuplot` quietly ignores undefined values, so the final branch of
 the function (1/0) will produce no plottable points.  Note also that it is
 plotted as a continuous function across the discontinuity if a line style is
 used.  If you want it to be plotted discontinuously, create separate
 functions for the two pieces.

 For data in a file, plot the average of the data in columns 2 and 3 against
 the datum in column 1, but only if the datum in column 4 is non-negative:

        plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )

 Please see `plot data-file using` for an explanation of the `using` syntax.
2 fit
?fit
 This implementation incorporates the capability of nonlinear least squares
 fitting using the Marquardt-Levenberg Algorithm.  It may fit any user-defined
 function to any set of data pairs (x,y).  x, y and the function's return type
 MUST be real!  Any variable occurring in the function body may serve as a fit
 parameter (fitting functions without adjustable parameters make no sense).

 Syntax:
         fit {range} <function> '<datafile>' {datafile-modifiers} \
             via {'<parameter file>' | <var1>,<var2>,...}

 Notice that `via` is now a required keyword, to distinguish it from a scanf
 format string.

 {[range]} is [ {variable=} { <min> } { :<max> } ], allowing the range of the
 fit to be limited temporarily in a manner analogous to `plot`.  <function> is
 any valid `gnuplot` expression, although it is usual to use a previously
 user-defined function of the form f(x).  <datafile> is treated as in the
 `plot` command.  All the modifiers for datafiles (`using`, `every`,...) in
 `plot` are available here---see `plot datafile` for full details.  The
 default column for x is 1 for y is 2.  They may be changed by the `using x:y`
 mechanism.  If a third column or expression is specified with `using`,
 uncertainties are read for each y value, to be used as weights during the
 fit.  Otherwise all data are weighted equally.  The start parameters may be
 specified in a (load-) file wherein each line is of the form:

    varname = value

 Comments, marked by '#', and blank lines are permissible.  The form

    varname = value       # FIXED

 means that the variable is treated as a `fixed parameter` that is initialized
 but will not be adjusted.  It is not necessary (but sometimes useful for
 clarity) to specify them at all.  The keyword '# FIXED' has to appear in
 exactly this form.

 The other means of specifying the adjustable parameters is to provide a
 comma-separated list of variable names after the `via` keyword.  If any of
 these variables do not yet exist within the current `gnuplot` session, they
 are created with an initial value of 1.0, but the fit is more likely to
 converge if a more appropriate starting value is given.  If this form is
 used, it may prove beneficial to iterate the fit, allowing only one or two
 variables to be adjusted at a time until a reasonably close fit is obtained,
 before allowing `fit` to vary all parameters.

 After each iteration step, detailed information is given about the fit's
 state, both on the screen and on a logfile "fit.log".  This file will never
 be erased but always appended to so that the fit's history isn't lost.  After
 each iteration step, the fit may be interrupted by pressing Ctrl-C (any key
 BUT Ctrl-C under MSDOS and Atari Multitasking Systems).  Then you have the
 options of stopping (and accepting the current parameter values), continuing
 the iteration of the fit, or executing a `gnuplot` command specified by an
 environment variable FIT_SCRIPT.  A `plot` or `load` command may be useful in
 this context.

 Special `gnuplot` variables:
    FIT_INDEX  contains the current data point number during execution,
               starting with 1.  You may use it in your fit function to
               implement multiple-branch fits.
    FIT_LIMIT  may be specified to change the default epsilon limit (1e-5).
               When the sum of squared residuals changes between two iteration
               steps by less than a factor of this number, the fit is
               considered to have 'converged'.

 (FIT_SKIP was available in previous released of gnufit.  Its functionality
 is now obtained using the `every` modifier for datafiles.)

 Environment variables:
    FIT_LOG    changes the logfile's path from './fit.log' (write permission
               is necessary).
    FIT_SCRIPT specifies a command to be executed after an user interrupt.

 Examples:
    f(x) = a*x**2 + b*x + c
    fit f(x) 'measured.dat' via 'start.par'
    fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
    fit f(x) './data/trash.dat' using 1:2:3 via a, b, c

 SEE ALSO: `update`
2 help
?help
 The `help` command displays on-line help. To specify information on a
 particular topic use the syntax:

         help {<topic>}

 If <topic> is not specified, a short message is printed about `gnuplot`.
 After help for the requested topic is given, a menu of subtopics is given;
 help for a subtopic may be requested by typing its name, extending the help
 request.  After that subtopic has been printed, the request may be extended
 again or you may go back one level to the previous topic.  Eventually, the
 `gnuplot` command line will return.

 If a question mark (?) is given as the topic, the list of topics currently
 available is printed on the screen.
2 if
?if
 The `if` command allows commands to be executed conditionally.

 Syntax:
         if (<condition>) <command-line>

 <condition> will be evaluated.  If it is true (non-zero), then the command(s)
 of the <command-line> will be executed.  If <condition> is false (zero), then
 the entire <command-line> is ignored.  Note that use of ';' to allow multiple
 commands on the same line will NOT end the conditionalized commands.

 Examples:

      pi=3
      if (pi!=acos(-1)) pause 0 "?Fixing pi!";pi=acos(-1);show variables

 will display:

      ?Fixing pi!

              Variables:
              pi = 3.14159
 but
      if (1==2) pause 0 "Never see this";pause 0 "Or this either"

 will not display anything.
2 load
?load
 The `load` command executes each line of the specified input file as if it
 had been typed in interactively.  Files created by the `save` command can
 later be `load`ed.  Any text file containing valid commands can be created
 and then executed by the `load` command.  Files being `load`ed may themselves
 contain `load` or `call` commands.  See `comment` for information about
 comments in commands.

 The `load` command MUST be the last command on a multi-command line.

 Syntax:
         load "<input-file>"

 The name of the input file must be enclosed in quotes.

 Examples:

         load 'work.gnu'
         load "func.dat"

 The `load` command is performed implicitly on any file names given as
 arguments to `gnuplot`.  These are loaded in the order specified, and
 then `gnuplot` exits.  See also `call`.
2 pause
?pause
 The `pause` command displays any text associated with the command and then
 waits a specified amount of time or until the carriage return is pressed.
 `pause` is especially useful in conjunction with `load` files.

 Syntax:
         pause <time> {"<string>"}

 <time> may be any integer constant or expression.  Choosing -1 will wait
 until a carriage return is hit, zero (0) won't pause at all, and a positive
 integer will wait the specified number of seconds.

 Note: Since `pause` is not part of the plot, it may interact with different
 device drivers differently (depending upon how text and graphics are mixed).

 Examples:
         pause -1    # Wait until a carriage return is hit
         pause 3     # Wait three seconds
         pause -1  "Hit return to continue"
         pause 10  "Isn't this pretty?  It's a cubic-spline."

2 plot
?plot
?splot
 `plot` and `splot` are the primary commands of the program. They plot
 functions and data in many, many ways.  `plot` is used to plot 2-d
 functions and data, while `splot` plots 3-d surfaces and data.

 Syntax:
      plot {ranges} {<function> | {"<datafile>" {datafile-modifiers}}} \
              {title} {style} {, {second,} <function> {title} {style}...}
      splot {ranges} {<function> | {"<datafile>" {datafile-modifiers}}} \
              {title} {style} {, <function> {title} {style}...}

 where either a <function> or the name of a data file enclosed in quotes is
 supplied.  A function is a mathematical expression, or a pair (`plot`) or
 triple (`splot`) of mathematical expressions in the case of parametric
 functions.  It is also possible to insert user-defined function definitions
 and variable assignments into the list of plots.

 For `plot` there are two independent sets of axes available: the keywords
 `first` and `second` can be used to change the axes for which the following
 plots should be scaled.  `first` refers to the axes on the bottom and
 left; `second` to those on the top and right.  Ranges specified on the `plot`
 command apply only to the first set of axes.

 The `second` option has not been implemented for `splot`.

 `plot` and `splot` commands can be as simple as

         plot sin(x)

 and

         splot x * y

 or as complex as (!)

  plot [t=1:10] [-pi:pi*2] tan(t), "data.1" using 2:($3/$4) with lines, \
        f(x)=x**p, p=2, second, f(t) with points
3 data-file
?plot data-file
?plot datafile
?splot data-file
?splot datafile
?data-file
?datafile
?data
 Discrete data contained in a file can be displayed by specifying the name of
 the data file (enclosed in quotes) on the `plot` or `splot` command line.

 Syntax:
         plot '<file_name>' {binary} {index <index list>} \
          {every <every list>} {thru <thru list>} {using <using list>}

 The modifiers `binary`, `index`, `every`, `thru`, and `using` are discussed
 separately.  In brief, `index` selects which data sets in a multi-data-set
 file are to be plotted, `every` selects which lines within a single data set
 are to be plotted, `using` determines how the columns within a single line
 are to be interpreted, `thru` is a special case of `using`, and `binary` is a
 flag for `splot` indicating that the file is binary.

 Data files should contain one data point per line.  Lines beginning with #
 (or ! on VMS) will be treated as comments and ignored.  For `plot`s, each
 data point represents an (x,y) pair.  For `splot`s, each point is an (x,y,z)
 triple.  For `plot`s with error bars (see `set style errorbars`), each data
 point is (x,y,ydelta), (x,y,ylow,yhigh), (x,y,xdelta), (x,y,xlow,xhigh), or
 (x,y,xlow,xhigh,ylow,yhigh).  In all cases, the numbers on each line of a
 data file must be separated by white space (one or more blanks or tabs),
 unless a format specifier is provided by the `using` option.  This white
 space divides each line into columns.

 For `plot`s, only one column (the y value) need be provided.  For `splot`s,
 provide either one column (z) or three (x,y,z).  (It is no longer necessary
 to specify `parametric` mode for three-column splots.)  If x (and y) are
 omitted, `gnuplot` provides integer values starting at 0.

 In `s/plot` datafiles, blank lines (lines with no characters other than a
 line feed or carriage return) are significant---pairs of blank lines separate
 `index`es (see `plot datafile index`).  Data separated by double blank lines
 are treated as if they were in separate data files.

 Single blank lines separate points in a `plot`, or isolines in a `splot`.
 No line will join points separated by a blank line in either a `plot` or
 `splot`.  For `splot`, if all isolines (groups of contiguous points) are of
 equal length, `gnuplot` will draw cross-isolines in the opposite direction.
 This is termed "grid data", and is required for contouring (`set contour`)
 and hidden-line removal (`set hidden3d`).

 If autoscaling has been enabled (`set autoscale`), the axes are automatically
 extended to include all datapoints, with a whole number of tic marks if tics
 are being drawn.  This has two consequences: i) For `splot`, the corner of
 the surface may not coincide with the corner of the base.  In this case, no
 vertical line is drawn.  ii) When plotting data with the same x range on a
 dual-axis plot, the x co-ordinates may not coincide if the x2tics are not
 being drawn.  This is because the x axis has been autoextended to a whole
 number of tics, but the x2 axis has not.  The following example illustrates
 the problem:

       reset; plot first, '-', second, '-'
       1 1
       19 19
       e
       1 1
       19 19
       e
4 binary
?binary
?binary data
?binary files
 In previous versions, `gnuplot` dynamically detected binary data files.  It
 is now necessary to specify the keyword `binary` directly after the filename.
 Currently, binary data is supported only for `splot`, since a format for
 binary data in 2-d has not been designed.

 Single precision floats are stored in a binary file as follows:

       <ncols> <x0> <x1> <x2> ...
       <y0> <z0,0> <z0,1> <z0,2> ...
       <y1> <z1,0> <z1,1> <z1,2> ...

 which are converted into triplets:

       <x0> <y0> <z0,0>
       <x0> <y1> <z0,1>
       <x0> <y2> <z0,2>

       <x1> <y0> <z1,0>
       <x1> <y1> <z1,1>
       <x1> <y2> <z1,2>

 These triplets are then converted into `gnuplot` iso-curves and then
 `gnuplot` proceeds in the usual manner to do the rest of the plotting.

 A collection of matrix and vector manipulation routines (in C) is provided
 in `binary.c`.  The routine to write binary data is

  int fwrite_matrix(file,m,nrl,nrl,ncl,nch,row_title,column_title)

 An example of using these routines is provided in the file `bf_test.c`, which
 generates binary files for the demo file `demo/binary.dem`.

 The `index` keyword is not supported, since the file format allows only one
 surface per file.  The `every` and `using` filters are supported.  `using`
 operates as if the data were read in the above triplet form.
^ <a href=binary/binary.html>Binary File Splot Demo.</a>
4 every
?plot data-file every
?plot datafile every
?splot data-file every
?splot datafile every
?every
 The `every` keyword allows a periodic sampling of a data set to be plotted.

 Syntax:
       plot 'file' every a{:b{:c{:d}}}

 This selects every a-th point in every b'th (iso)line, starting at point c in
 line d.  To plot a single line from a 3-d datafile, one trick is to set d to
 the required line, and set b very large, so that no subsequent lines will be
 selected.  If `every` is not specified, all points are plotted.

 Following C indexing, the first point (and the first isoline) are assigned
 the index 0.
^ <a href=simple/simple.html>Simple Plot Demos </a>,
^ <a href=surfacea/surfacea.html>Non-parametric splot demos </a>, and
^ <a href=surfaceb/surfaceb.html>Parametric splot demos.</a>
4 example
?plot data-file example
?plot datafile example
?datafile example
 This example compares the data in the file population.dat to a theoretical
 curve:

         pop(x) = 103*exp((1965-x)/10)
         plot [1960:1990] 'population.dat', pop(x)

 The file population.dat might contain:

         # Gnu population in Antarctica since 1965
         1965   103
         1970   55
         1975   34
         1980   24
         1985   10



 A simple example of plotting a 3-d data file is

         splot 'glass.dat'

 where the file datafile.dat might contain:

         # The valley of the Gnu.
         0 0 10
         0 1 10
         0 2 10

         1 0 10
         1 1 5
         1 2 10

         2 0 10
         2 1 1
         2 2 10

         3 0 10
         3 1 0
         3 2 10

 Note datafile.dat defines a 4 by 3 grid ( 4 rows of 3 points each ).  Rows
 are separated by blank lines.

 Note also that the x value is held constant within each isoline.  If you
 instead keep y constant, and plot with hidden-line removal enabled, you will
 find that the surface is drawn 'inside-out'.

 Actually it is not necessary to keep the x values constant within an isoline,
 nor is it necessary to keep the y values the same along the perpendicular
 isolines.  `gnuplot` requires only that the number of points be the same
 along each isoline.
4 index
?plot data-file index
?plot datafile index
?splot data-file index
?splot datafile index
?index
 The `index` keyword allows only some of the data sets in a multi-data-set
 file to be plotted.

 Syntax:
      plot 'file' index m{{:n}:p}

 Data sets (surfaces for `splot`) are separated by pairs of blank lines.
 `index m` selects only set m; `index m:n` selects sets in the range m to n;
 and `index m:n:p` selects indices m, m+p, m+2p, etc., but stopping at n.
 Following C indexing, the index 0 is assigned to the first data set in
 the file.  Specifying too large an index results in an error message.  If
 `index` is not specified, all sets are plotted.

 Example:
          plot 'file' index 4:5
^ <a href=multimsh/multimsh.html> splot with indices demo. </a>
4 thru
?plot data-file thru
?plot datafile thru
?splot data-file thru
?splot datafile thru
?thru
 The `thru` function is provided for backward compatibility.

 Syntax:
         plot 'file' thru f(x)

 It is equivalent to `plot 'file' using 1:(f($2))`.  While the latter appears
 more complex, it is much more flexible.

 The more natural

   plot 'file' thru f(y)

 also works (i.e. you can use y as the dummy variable).

 `thru` is parsed for `splot` and `fit` but has no effect.
4 special-filenames
?plot data-file special-filenames
?plot datafile special-filenames
?datafile special-filenames
 A special filename of `'-'` specifies that the data are inline; i.e., they
 follow the command.  Only the data follow the command; `plot` options like
 filters, titles, and line styles remain on the 'plot' command line.  This is
 similar to << in unix shell script, and $DECK in VMS DCL.  The data are
 entered as though they are being read from a file, one data point per record.
 The letter "e" at the start of the first column terminates data entry.  The
 `using` option can be applied to these data---using it to filter them through
 a function might make sense, but selecting columns probably doesn't!

 N.B.---use of

   plot '-' ; ... ; replot

 is not recommended---`gnuplot` does not store the inline data internally.
 Since `replot` appends new information to the previous `plot` and then
 executes the modified command, the `'-'` will ask once more for the data.
 `'-'` is intended for situations where it is useful to have data and commands
 together, e.g., when `gnuplot` is run as a sub-process of some front-end
 application.  Some of the demos, for example, might use this feature.

 A blank filename ('') specifies that the previous filename should be reused.
 This can be useful with things like

  plot 'a/very/very/long/filename' using 1:2, '' using 1:3, '' using 1:4

 On some computer systems with a popen function (Unix), the datafile can be
 piped through a shell command by starting the file name with a '<'.  For
 example

         pop(x) = 103*exp(-x/10)
         plot "< awk '{print $1-1965, $2}' population.dat", pop(x)

 would plot the same information as the first population example but with
 years since 1965 as the x axis.  If you want to execute this example, you
 have to delete all comments from the data file above or substitute the
 following command for the first part of the command above (the part up to
 the comma):

         plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"

 While this approach is most flexible, it is possible to achieve simple
 filtering with the `using` or `thru` keywords.
4 using
?plot data-file using
?plot datafile using
?splot data-file using
?splot datafile using
?using
 The most common datafile modifier is `using`.

 Syntax:
         plot 'file' using { spec:spec:... } {'format'}

 If a format is specified, each datafile line is read using the c library's
 scanf function, with the specified format string.  Otherwise the line is read
 and broken into columns at spaces or tabs.  A format cannot be specified if
 time-format data is being used  (see `set data time`).

 The resulting array of data is then sorted into columns according to the
 specs.  Each spec is either a simple column number, which selects the datum,
 or an expression enclosed in round brackets (parentheses).  The expression
 can use $1 to access the first item read, $2 for the second item, and so on.
 It can also use `column(x)` and `valid(x)` where x is an arbitrary expression
 resulting in an integer.  `column(x)` returns the x'th datum; `valid(x)`
 tests that datum x is a valid number.  A column number of 0 generates a
 number increasing (from zero) with each point, reset at double blank lines.

 `plot 'file' using 1` is identical to `plot 'file' using 0:1`.

 N.B.---the `call` command also uses $'s as a special character.

 The interpretation of the columns depends on the plot and style.  For
 `splot`, a single column is z, or three columns are (x,y,z) (unless `set
 mapping` has been used).  For `plot`, a single column is y.  For `plot` or
 `fit`, the first two columns are x and y; additional columns are usually
 errors in x and/or y.  See `set style` for more details about the structure
 of files containing error information.

 Examples:

 This creates a plot of the sum of the 2nd and 3rd data against the first:
 (The format string specifies comma- rather than space-separated columns.)
     plot 'file' using 1:($2+$3) '%lf,%lf,%lf'

 In this example the data are read from the file "MyData" using a more
 complicated format:
     plot "MyData" using "%*lf%lf%*20[^\n]%lf"

 The meaning of this format is:

       %*lf        ignore the first number
       %lf         read in the second and assign to x
       %*20[^\n]   ignore 20 non-newline characters
       %lf         read in the y value

 Note that the use of newline (\n) requires use of double-quotes rather than
 single-quotes.

 One trick is to use the ternary `?:` operator to filter data:

       plot 'file' using 1:($3>10 ? $2 : 1/0)

 which plots the datum in column two against that in column one provided
 the datum in column three exceeds ten.  `1/0` is undefined; `gnuplot`
 quietly ignores undefined points, so unsuitable points are suppressed.

 In fact, you can use a constant expression for the column number, provided
 it doesn't start with an opening bracket.  Something like

      `using 0+`(complicated expression)

 can be used.  The crucial point is that the expression is evaluated once if
 it doesn't start with a bracket, or once for each data point read if it does
 start with a bracket.

 If timeseries data are being used, the time can span multiple columns.  The
 starting column should be specified.  Note that the spaces within the time
 must be included when calculating starting columns for other data.  E.g., if
 the first element on a line is a time with an embedded space, the y value
 should be specified as column three.

 It should be noted that `plot 'file', plot 'file' using 1:2`, and `plot
 'file' using ($1):($2)` can be subtly different: 1) if `file` has some lines
 with one column and some with two, the first will invent x values when they
 are missing, the second will quietly ignore the lines with one column, and
 the third will store an undefined value for lines with one point (so that in
 a plot with lines, no line joins points across the bad point); 2) if a line
 contains text at the first column, the first will abort the plot on an error,
 but the second and third should quietly skip the garbage.

 In fact, it is often possible to plot a file with lots of lines of garbage at
 the top simply by specifying

    plot 'file' using 1:2

 If you want to leave text in your data files, it is always safe to put the
 comment character (#) in the first column of the text lines.
^ <a href=using/using.html> Using Demos.</a>
3 errorbars
?plot errorbars
?errorbars
 Error bars are supported for 2-d data file plots by reading one to
 four additional columns specifying ydelta or ylow and yhigh for
 yerrorbars or xdelta or xlow and xhigh for xerrorbars or xdelta, ydelta
 or xlow, xhigh, ylow, yhigh for xyerrorbars or boxxyerrorbars.
 No support exists for any error bars for `splot`s.

 In the default situation, `gnuplot` expects to see three, four, or six
 numbers on each line of the data file---either (x, y, ydelta),
 (x, y, ylow, yhigh), (x, y, xdelta), (x, y, xlow, xhigh),
 (x, y, xdelta, ydelta), or (x, y, xlow, xhigh, ylow, yhigh).  The
 x co-ordinate must be specified. The order of the numbers must be
 exactly as given above, though the `using` qualifier can manipulate
 the order and provide values for missing columns.  For example,

   plot 'file' with errorbars
   plot 'file' using 1:2:(sqrt($1)) with xerrorbars
   plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

 The last plot is for a file with an unsupported combination of relative
 x and absolute y errors. The `using` spec generates absolute x min and
 max from the relative error.

 The y error bar is a vertical line plotted from (x, ylow) to (x, yhigh).
 If ydelta is specified instead of ylow and yhigh, ylow = y - ydelta and
 yhigh = y + ydelta are derived.  If there are only two numbers on the line,
 yhigh and ylow are both set to y.  The x error bar is a horizontal line
 computed in the same fashion.  To get lines plotted between the data points,
 `plot` the data file twice, once with errorbars and once with lines.

 The error bar has crossbars at top and bottom unless `set bar small` is used.

 If autoscaling is on, the ranges will be adjusted to fit the error bars.
^ <a href=errorbar/errorbar.html> Errorbar demos. </a>

 See `plot using`, `plot with`, and `set style` for more information.
3 parametric
?plot parametric
?splot parametric
?parametric
 When in parametric mode (`set parametric`) mathematical expressions must be
 given in pairs for `plot` and in triplets for `splot`:

         plot sin(t),t**2
 or
         splot cos(u)*cos(v),cos(u)*sin(v),sin(u)

 Data files are plotted as before, except any preceding parametric function
 must be fully specified before a data file is given as a plot.  In other
 words, the x parametric function (`sin(t)` above) and the y parametric
 function (`t**2` above) must not be interrupted with any modifiers or data
 functions; doing so will generate a syntax error stating that the parametric
 function is not fully specified.

 Ranges take on a different meaning when in parametric mode.  The first range
 on the `plot` command is the `trange`, the next is the `xrange`, and the last
 is the `yrange`.  For `splot` the order is `urange`, `vrange`, `xrange`,
 `yrange`, and finally `zrange`.  The following `plot` command shows setting
 the `trange` to [-pi:pi], the `xrange` to [-1.3:1.3] and the `yrange` to
 [-1:1] for the duration of the plot:

         plot [-pi:pi] [-1.3:1.3] [-1:1] sin(t),t**2

 Other modifiers, such as `with` and `title`, may be specified only after the
 parametric function has been completed:

         plot sin(t),t**2 title 'Parametric example' with linespoints
^ <a href=param/param.html> Parametric Mode Demos. </a>
3 ranges
?splot ranges
?plot ranges
?ranges
 The optional ranges specify the region of the plot that will be displayed.

 Syntax:
         [{<dummy-var> =} {<xmin>} { : <xmax>}] { [{<ymin>} {: <ymax>}] }

 where <dummy-var> is the independent variable (the defaults are x and y,
 but these may be changed with `set dummy`) and the min and max terms can be
 constant expressions.

 * can be used to allow autoscaling of either of min and max.  See also
 `set autoscaling`

 Ranges specified on the `plot` or `splot` command line affect only that plot;
 use the `set xrange`, `set yrange`, etc., commands to change the default
 ranges for future plots.

 With time data, you must provide the range (in the same manner as the time
 appears in the datafile) within quotes.  `gnuplot` uses the `timefmt` string
 to read the value---see `set timefmt`.

 Examples:

 This uses the current ranges:
         plot cos(x)

 This sets the x range only:
         plot [-10:30] sin(pi*x)/(pi*x)

 This is the same, but uses t as the dummy-variable:
         plot [t = -10 :30]  sin(pi*t)/(pi*t)

 This sets both the x and y ranges:
         plot [-pi:pi] [-3:3]  tan(x), 1/x

 This sets only the y range, and turns off autoscaling on both axes:
         plot [ ] [-2:sin(5)*-8] sin(x)**besj0(x)

 This sets xmax and ymin only:
         plot [:200] [-pi:]  exp(sin(x))

 This sets the x, y, and z ranges:
         splot [0:3] [1:4] [-1:1] x*y

 This sets the x range for a timeseries (timefmt="%d/%m/%y %H:%M"):
         plot ["1/6/93 12:00":"5/6/93 12:00"] 'timedata.dat'
3 style
?plot style
?splot style
?style
?plot with
?with
 Functions and data may be displayed in one of a large number of styles.
 The `with` keyword provides the means of selection.

 Syntax:
         with <style> {<linetype> {<pointtype>}}

 where <style> is either `lines`, `points`, `linespoints`, `impulses`, `dots`,
 `steps`, `fsteps`,  `errorbars`, `xerrorbars`, `yerrorbars`, `xyerrorbars`,
 `boxes`, `boxerrorbars`, `boxxyerrorbars`, `splines`, `csplines`, `bezier`,
 `sbezier`, or `vector`.  A given style may not be appropriate for both 2-D
 and 3-D plots and may require additional information.  See `set style
 <style>` for details about each style.

 Default styles are chosen with the `set function style` and `set data style`
 commands.

 By default, each function and data file will use a different line type and
 point type, up to the maximum number of available types.  All terminal
 drivers support at least six different point types, and re-use them, in
 order, if more than six are required.  The LaTeX driver supplies an
 additional six point types (all variants of a circle), and thus will only
 repeat after twelve curves are plotted with points.  The PostScript drivers
 (`postscript`) supplies a total of sixty-four.

 If you wish to choose the line or point type, <linetype> and <pointtype> may
 be specified.  These are positive integer constants (or expressions) that
 specify the line type and point type to be used for the plot.

 Use `test` to display the types available for your terminal.

 Examples:

 This plots sin(x) with impulses:
         plot sin(x) with impulses

 This plots x*y with points, x**2 + y**2 default:
         splot x*y w points, x**2 + y**2

 This plots tan(x) with the default function style, "data.1" with lines:
         plot [ ] [-2:5] tan(x), "data.1" with l

 This plots "leastsq.dat" with impulses:
         plot 'leastsq.dat' w i

 This plots the data file 'population' with boxes:
         plot "population" with boxes

 This plots "exper.dat" with errorbars and lines connecting the points:
         plot 'exper.dat' w lines, 'exper.dat' w errorbars

 Here 'exper.dat' should have three or four data columns.

 This plots x**2 + y**2 and x**2 - y**2 with the same line type:
         splot x**2 + y**2 with line 1, x**2 - y**2 with line 1

 This plots sin(x) and cos(x) with linespoints, using the
 same line type but different point types:
         plot sin(x) with linesp 1 3, cos(x) with linesp 1 4

 This plots file "data" with points style 3:
         plot "data" with points 1 3
 Note that the line style must be specified when specifying the point
 style, even when it is irrelevant. Here the line style is 1 and the
 point style is 3, and the line style is irrelevant.

 See `set style` to change the default styles.
3 title
?plot title
?splot title
 A title of each plot appears in the key.  By default the title is the
 function or file name as it appears on the plot command line.  The title
 can be changed by using the `title` option.  This option should precede
 any `with` option.

 Syntax:
         title "<title>" | notitle

 where <title> is the new title of the plot and must be enclosed in quotes.
 The quotes will not be shown in the key.  A special character may be given as
 a backslash followed by its octal value ("\345").  The tab character "\t" is
 understood.  Note that backslash processing occurs only for strings enclosed
 in double quotes---use single quotes to prevent such processing.

 Examples:

 This plots y=x with the title 'x':
         plot x

 This plots the "glass.dat" file with the title 'surface of revolution':
         splot "glass.dat" title 'surface of revolution'

 This plots x squared with title "x^2" and "data.1" with title 'measured
 data':
         plot x**2 title "x^2", "data.1" t 'measured data'

 The title can be omitted from the key by using the keyword `notitle`.  This
 can be useful when some curves are plotted solely for decoration.  For
 example, if one wanted a circular border for a polar plot, he could say:

 Example:
        set polar
        plot my_function(x), 1 notitle

 This would generate a key entry for "my_function" but not for "1".  See the
 poldat.dem example.  `title ''`  is equivalent to `notitle`.  `title ' '`
 can be used to have a sample with no text.
2 print
?print
 The `print` command prints the value of <expression> to the screen.

 Syntax:
         print <expression>

 See `expressions`.
2 pwd
?pwd
 The `pwd` command prints the name of the working directory to the screen.

 Syntax:
         pwd
2 quit
?quit
 The `exit` and `quit` commands and END-OF-FILE character will exit `gnuplot`.
 Each of these commands will clear the output device (as does the `clear`
 command) before exiting.
2 replot
?replot
 The `replot` command without arguments repeats the last `plot` or `splot`
 command.  This can be useful for viewing a plot with different `set`
 options, or when generating the same plot for several devices.

 Arguments specified after a `replot` command will be added onto the last
 `plot` or `splot` command (with an implied ',' separator) before it is
 repeated.  `replot` accepts the same arguments as the `plot` and `splot`
 commands except that ranges cannot be specified.  Thus you can use `replot`
 to plot a function against the second axes if the previous command was `plot`
 but not if it was `splot`, and similarly you can use `replot` to add a plot
 from a binary file only if the previous command was `splot`.

 N.B.---use of

   plot '-' ; ... ; replot

 is not recommended---`gnuplot` does not store the inline data internally.
 Since `replot` appends new information to the previous `plot` and then
 executes the modified command, the `'-'` will ask once more for the data.
 `'-'` is intended for situations where it is useful to have data and commands
 together, e.g., when `gnuplot` is run as a sub-process of some front-end
 application.  Some of the demos, for example, might use this feature.

 See `command-line-editing` for ways to edit the last `plot`
 (`splot`) command.
2 reread
?reread
 The `reread` command causes the current `gnuplot` command file, as specified
 by a `load` command or on the command line, to be reset to its starting
 point before further commands are read from it.  This essentially implements
 an endless loop of the commands from the beginning of the command file to
 the `reread` command.  The `reread` command has no effect if input from
 standard input.
^ <a href=animate/animate.html> Reread Animation </a>
2 reset
?reset
 The `reset` command causes all options that can be set with the `set`
 command to take on their default values.  The only exceptions are that the
 terminal set with `set term` and the output file set with `set output` are
 left unchanged.  This command is useful, e.g., to restore the default
 settings at the end of a command file, or to return to a defined state after
 lots of settings have been changed within a command file.  Please refer to
 the `set` command to see the default values that the various options take.
2 save
?save
 The `save` command saves user-defined functions, variables, `set` options,
 or all three, plus the last `plot` (`splot`) command to the specified file.

 Syntax:
         save  {<option>} "<filename>"

 where <option> is `functions`, `variables` or `set`. If no option is used,
 `gnuplot` saves functions, variables, `set` options and the last `plot`
 (`splot`) command.

 `save`d files are written in text format and may be read by the `load`
 command.

 The filename must be enclosed in quotes.

 Examples:

         save "work.gnu"
         save functions 'func.dat'
         save var 'var.dat'
         save set "options.dat"
2 set-show
?set
?show
?show all
 The `set` command sets LOTS of options.

 The `show` command shows their settings.  `show all` shows all the
 settings.
3 angles
?set angles
?show angles
?angles
?set angles degrees
 By default, `gnuplot` assumes the independent variable in polar plots is in
 units of radians.  If `set angles degrees` is specified before `set polar`,
 then the default range is [0:360] and the independent variable has units of
 degrees.  This is particularly useful for plots of data files.  The angle
 setting also applies to 3-d mapping as set via the `set mapping` command.

 Syntax:
         set angles { degrees | radians }
         show angles

 The angle specified in `set grid polar` is also read and displayed in the
 units specified by `set angles`.

 `set angles` has no effect on the arguments of machine-defined functions
 (sin(x), cosh(x), besj0(x), etc.); neither does it affect the result of
 inverse trigonometric functions, e.g. atan(x).  These are always given in
 radians.
3 arrow
?set arrow
?set noarrow
?show arrow
?arrow
?noarrow
 Arbitrary arrows can be placed on a plot using the `set arrow` command.

 Syntax:
          set arrow {<tag>} {from <position>} \
                            {to <position>} {{no}head} \
                            {<linestyle>}
          set noarrow {<tag>}
          show arrow


 Unspecified co-ordinates default to 0.  The endpoints can be specified in
 one of four co-ordinate systems---`first` or `second` axes, `graph` or
 `screen`.  See `set co-ordinates` for details.  Arrows outside the screen
 boundaries are permitted but may cause device errors.

 <tag> is an integer that identifies the arrow.  If no tag is given, the
 lowest unused tag value is assigned automatically.  The tag can be used to
 delete or change a specific arrow.  To change any attribute of an existing
 arrow, use the `set arrow` command with the appropriate tag and specify the
 parts of the arrow to be changed.

 Specifying `nohead` produces an arrow drawn without a head---a line segment.
 This gives you yet another way to draw a line segment on the graph.  By
 default, arrows have heads.

 `linestyle` allows specification of the line style to be used for the arrow.

 Examples:

 To set an arrow pointing from the origin to (1,2), use:
          set arrow to 1,2
 To set an arrow from bottom left of plotting area to (-5,5,3), and tag the
 arrow number 3, use:
          set arrow 3 from graph 0,0 to -5,5,3
 To change the preceding arrow to end at 1,1,1, without an arrow head, use:
          set arrow 3 to 1,1,1 nohead
 To draw a vertical line from the bottom to the top of the graph at x=3, use:
          set arrow from 3, graph 0 to 3, graph 1 nohead
 To delete arrow number 2 use:
          set noarrow 2
 To delete all arrows use:
          set noarrow
 To show all arrows (in tag order) use:
          show arrow
3 autoscale
?set autoscale
?set noautoscale
?show autoscale
?autoscale
?noautoscale
 Autoscaling may be set individually on the x, y or z axis or globally on all
 axes. The default is to autoscale all axes.

 Syntax:
         set autoscale <axes>{min|max}
         set noautoscale <axes>{min|max}
         show autoscale

 where <axes> is either `x`, `y`, `z`, `x2`, `y2` or `xy`.  A keyword with
 `min` or `max` appended (this cannot be done with `xy`) tells `gnuplot` to
 autoscale just the minimum or maximum of that axis.  If no keyword is given,
 all axes are autoscaled.

 When autoscaling, the plot range is automatically computed and the dependent
 axis (y for a `plot` and z for `splot`) is scaled to include the range of the
 function or data being plotted.

 If autoscaling of the dependent axis (y or z) is not set, the current y or z
 range is used.

 Autoscaling the independent variables (x for `plot` and x,y for `splot`) is a
 request to set the domain to match any data file being plotted.  If there are
 no data files, autoscaling an independent variable has no effect.  In other
 words, in the absence of a data file, functions alone do not affect the x
 range (or the y range if plotting z = f(x,y)).

 Please see `set range` for additional information about ranges.

 The behavior of autoscaling remains consistent in parametric mode, (see `set
 parametric`).  However, there are more dependent variables and hence more
 control over x, y, and z plot scales.  In parametric mode, the independent
 or dummy variable is t for `plot`s and u,v for `splot`s.  `autoscale` in
 parametric mode, then, controls all ranges (t, u, v, x, y, and z) and allows
 x, y, and z to be fully autoscaled.

 When tics are displayed on second axes but no plot has been specified for
 those axes, x2range and y2range are inherited from xrange and yrange.  This
 is done _before_ xrange and yrange are autoextended to a whole number of
 tics, which can cause unexpected results.

 Examples:

 This sets autoscaling of the y axis (other axes are not affected):
         set autoscale y

 This sets autoscaling only for the minimum of the y axis (the maximum of the
 y axis and the other axes are not affected):
         set autoscale ymin

 This sets autoscaling of the x and y axes:
         set autoscale xy

 This sets autoscaling of the x, y, z, x2 and y2 axes:
         set autoscale

 This disables autoscaling of the x, y, z, x2 and y2 axes:
         set noautoscale

 This disables autoscaling of the z axis only:
         set noautoscale z
4 parametric mode
?autoscale parametric
?set autoscale t
 When in parametric mode (`set parametric`), the  xrange is as fully scalable
 as the y range.  In other words, in parametric mode the x axis can be
 automatically scaled to fit the range of the parametric function that is
 being plotted.  Of course, the y axis can also be automatically scaled just
 as in the non-parametric case.  If autoscaling on the x axis is not set, the
 current x range is used.

 Data files are plotted the same in parametric and nonparametric mode.
 However, there is a difference in mixed function and data plots: in
 non-parametric mode with autoscaled x, the x range of the datafile controls
 the x range of the functions; in parametric mode it has no influence.

 For completeness a last command `set autoscale t` is accepted.  However, the
 effect of this "scaling" is very minor.  When `gnuplot` determines that the
 t range would be empty, it makes a small adjustment if autoscaling is true.
 Otherwise, `gnuplot` gives an error.  Such behavior may, in fact, not be very
 useful and the command `set autoscale t` is certainly questionable.

 `splot` extends the above ideas as you would expect.  If autoscaling is set,
 then x, y, and z ranges are computed and each axis scaled to fit the
 resulting data.
3 bar
?set bar
?show bar
 The `set bar` command controls the tics at the ends of errorbars.

 Syntax:
         set bar {small | large | <size>}
         show bar

 `small` is a synonym for 0.0, and `large` for 1.0.
 The default is 1.0 if no size is given.
3 bmargin
 The command `set bmargin` sets the size of the bottom margin.  Please see
 `set margins` for details.
3 border
?set border
?set noborder
?show border
?border
?noborder
 The `set border` and `set noborder` commands control the display of the plot
 borders for the `plot` and `splot` commands.  The borders are encoded in a
 twelve-bit integer: the bottom 4 bits control the border for `plot` and the
 sides of the base for `splot`.  The next 4 bits control the verticals in
 `splot`, while the top 4 bits control the edges on top of the `splot`.  The
 default is 31, which is all four sides for `plot`, and base and z axis for
 `splot`.

 Syntax:
         set border    (turns on all borders)
         set border 3  (only SOUTHWEST borders)
         set border 4095   (complete box around splot)
         set border 127+256+512  (partial box omitting front vertical)
         set noborder
         show border

 To have tics on edges other than bottom and left, disable the usual
 tics and enable the second axes.

         set border 12 (only NORTHEAST borders)
         set noxtics; set noytics; set x2tics; set y2tics
^ <a href=borders/borders.html> Borders Demo. </a>
3 boxwidth
?set boxwidth
?show boxwidth
?boxwidth
 The `set boxwidth` command is used to set the default width of boxes in the
 `boxes` and `boxerrorbars` styles.

 Syntax:
          set boxwidth {<width>}
          show boxwidth

 If a data file is plotted without the width being specified in the third,
 fourth, or fifth column, or if a function is plotted, the width of each box
 is set by the `set boxwidth` command.  (If a width is given after the `set
 boxwidth` command, the one taken from the data is used.)  If the width is
 not specified in one of these ways, the width of each box will be calculated
 automatically so that it touches the adjacent boxes.  In a four-column data
 set, the fourth column will be interpreted as the box width unless the width
 is set to -2.0, in which case the width will be calculated automatically.
 See `boxerrorbars` or `set style` for more details.

 To set the box width to automatic use the command
          set boxwidth
          set boxwidth -2  (4-col data)

 The same effect can be achieved with the `using` keyword in `plot`:
          plot 'file' using 1:2:3:4:(-2)
3 clabel
?set clabel
?set noclabel
?show clabel
?clabel
?noclabel
 `gnuplot` will vary the linetype used for each contour level when clabel is
 set.  When this option on (the default), a legend labels each linestyle with
 the z level it represents.  It is not possible at present to separate the
 contour labels from the surface key.

 Syntax:
         set clabel { 'format' }
         set noclabel
         show clabel

 The default for the format string is %8.3g, which gives three decimal places.
 This may produce poor label alignment if the key is altered from its default
 configuration.

 See also `set contour`.
3 clip
?set clip
?set noclip
?show clip
?clip
?noclip
 `gnuplot` can clip data points and lines that are near the boundaries of a
 plot.

 Syntax:
         set clip <clip-type>
         set noclip <clip-type>
         show clip

 Three clip types are supported by `gnuplot`: `points`, `one`, and `two`.
 One, two, or all three clip types may be active for a single plot.

 The `points` clip type forces `gnuplot` to clip (actually, not plot at all)
 data points that fall within but too close to the boundaries.  This is done
 so that large symbols used for points will not extend outside the boundary
 lines.  Without clipping points near the boundaries, the plot may look bad.
 Adjusting the x and y ranges may give similar results.

 Setting the `one` clip type causes `gnuplot` to plot a line segment which has
 only one of its two endpoints within the plotting region.  Only the in-range
 portion of the line is drawn.  The alternative is to not draw any portion of
 the line segment.

 Some lines may have both endpoints out of range, but pass through the
 plotting area.  Setting the `two` clip-type allows the visible portion of
 these lines to be drawn.

 In no case is a line drawn outside the plotting area.

 The defaults are `noclip points`, `clip one`, and `noclip two`.

 To check the state of all forms of clipping, use
         show clip

 For backward compatibility with older versions, the following forms are also
 permitted:
        set clip
        set noclip
 `set clip` is synonymous with `set clip points`; `set noclip` turns off all
 three types of clipping.
3 cntrparam
?set cntrparam
?show cntrparam
?cntrparam
 `set cntrparam` controls the generation of contours and their smoothness for
 a contour plot.

 Syntax:
         set cntrparam { { linear | cubicspline | bspline } |
              points <n> |
              order <n> |
              levels { [ auto ] <n> |
                       discrete <z1>,<z2>, ... |
                       incremental {<start>, <incr>{, <end>} } } }
         show cntrparam

 This command controls the way contours are plotted.  <n> should be an
 integral constant expression and <z1>, <z2> any constant expressions.
 The parameters are:

 `linear`, `cubicspline`, `bspline`---Controls type of approximation or
 interpolation.  If `linear`, then the contours are drawn piecewise linear, as
 extracted from the surface directly.  If `cubicspline`, then piecewise linear
 contours are interpolated to form somewhat smoother contours, but which may
 undulate.  If `bspline`, a guaranteed-smoother curve is drawn, which only
 approximates the piecewise linear data.

 `points`---Eventually all drawings are done with piecewise linear strokes.
 This number controls the number of points used to approximate a curve.
 It is relevant only for `cubicspline` and `bspline` modes.

 `order`---Order of the bspline approximation to be used.  The bigger this
 order is, the smoother the resulting contour.  (Of course, higher order
 bspline curves will move further away from the original piecewise linear
 data.)  This option is relevant for `bspline` mode only.  Allowed values are
 integers in the range from 2 (linear) to 10.

 `levels`---Number of contour levels.  Selection of the levels is controlled
 by `auto` (default), `discrete`, and `incremental`.  For `auto`, if the
 surface is bounded by zmin and zmax, contours will be generated from zmin+dz
 to zmax-dz in steps of size dz, where dz = (zmax - zmin) / (levels + 1).  For
 `discrete`, contours will be generated at z = z1, z2 ... as specified.  The
 number of discrete levels is limited to MAX_DISCRETE_LEVELS, defined in
 plot.h to be 30.  If `incremental`, contours are generated at values of z
 beginning at <start> and increasing by <increment> until <end> is reached.
 If <end> is not specified, MAX_DISCRETE_LEVELS will be generated.

 Examples:
     set cntrparam bspline
     set cntrparam points 7
     set cntrparam order 10
     set cntrparam levels auto 5                   # 5 automatic levels
     set cntrparam levels discrete .1,1/exp(1),.9  # 3 discrete at .1,.37,.9
     set cntrparam levels incremental  0,.1,.4
     # 5 incremental levels at 0, .1, .2, .3 and .4
     set cntrparam levels 10
     # sets n = 10 retaining current setting of auto, discr. and
     # increment's start and increment value, while changing end
     set cntrparam levels incremental 100,50
     # set start = 100 and increment = 50, retaining n levels

 See also `set contour` for control of where the contours are drawn, and `set
 clabel` for control of the format of the contour labels.
^ <a href=contours/contours.html>Contours Demo</a> and
^ <a href=discrete/discrete.html>contours with User Defined Levels.</a>
3 contour
?set contour
?show contour
?contour
 `set contour` enables contour drawing for surfaces. This option is available
 for `splot` only.

 Syntax:
         set contour { base | surface | both }
         set nocontour

 The three options specify where to draw the contours: `base` draws the
 contours on the grid base where the x/ytics are placed, `surface` draws the
 contours on the surfaces themselves, and `both` draws the contours on both
 the base and the surface.  If no option is provided, the default is `base`.

 See also `set cntrparam` for the parameters that affect the drawing of
 contours, and `set clabel` for control of labelling of the contours.

 The surface can be switched off (see `set surface`), giving a contour-only
 plot.  Though it is possible to set the view to give a full-page plot, good
 results can be obtained by writing the contour information out to a file, and
 rereading it as a 2-d datafile plot:

   set nosurface
   set contour
   set cntrparam ...
   set term table
   set out 'filename'
   splot ...
   set out
   # contour info now in filename
   set term <whatever>
   plot 'filename'

 In order to draw contours, the data must be organized as "grid data".  In
 such a file all of the points for a single y value are listed, then all the
 points for the next y, and so on.  A single null line (a line containing no
 characters other than a carriage return and/or a line feed) separates one y
 value group from the next.  See also `plot datafile`.

 If contours are desired from non-grid data, `set dgrid3d` can be used to
 create an appropriate grid.  See `set dgrid3d` for more information.
^ <a href=contours/contours.html>Contours Demo</a> and
^ <a href=discrete/discrete.html>contours with User Defined Levels.</a>
3 co-ordinates
?co-ordinates
 While there is no `set co-ordinates` command, the commands `set arrow`, `set
 key`, and `set label` allow you to draw something at an arbitrary position
 on the graph.  This position is specified by the syntax:

          {first | second | graph | screen} x,\
          {first | second | graph | screen} y\
          {, {first | second | graph | screen} z}

 `first` places the x, y, or z co-ordinate in the system defined by the left
 and bottom axes; `second` places it in the system defined by the second axes
 (top and right); `graph` specifies the area within the axes---0,0 is bottom
 left and 1,1 is top right (for splot, 0,0,0 is bottom left of plotting area;
 use negative z to get to the base---see `set ticslevel`); and `screen`
 specifies the screen area---0,0 is bottom left and 1,1 is top right.

 If the co-ordinate system is not specified, `first` is used.

 If one (or more) axis is timeseries, the appropriate co-ordinate should
 be given as a quoted time string according to the `timefmt` format string.
 See `set {x,y,z}data` and `set timefmt`.
3 data style
?set data style
?show data style
?data style
 The `set data style` command changes the default plotting style for data
 plots.

 Syntax:
         set data style <style-choice>
         show data style

 See `set style` for the choices.  If no choice is given, the choices are
 listed.  `show data style` shows the current default data plotting style.
3 dgrid3d
?set dgrid3d
?set nodgrid3d
?show dgrid3d
?dgrid3d
 The `set dgrid3d` command enables and sets the different parameters for
 non-grid to grid data mapping.

 Syntax:
         set dgrid3d {,{<row_size>}{,{<col_size>}{,<norm>}}}
         set nodgrid3d
         show dgrid3d

 By default `dgrid3d` is disabled.  When enabled, 3-d data read from a file
 are always treated as a scattered data set.  A grid with dimensions derived
 from a bounding box of the scattered data and size as specified by the
 row/col_size parameters is created for plotting and contouring.  The grid is
 equally spaced in x and y; the z values are computed as weighted averages of
 the scattered points' values.

 The third parameter, norm, controls the weighting: each point is weighted
 inversely by its distance (from the grid point) raised to the norm power.
 (Actually it's not quite the distance: the weights are given by the inverse
 of dx^norm + dy^norm, where dx and dy are the components of the separation
 of the grid point from each data point.)  Thus the closer the data point is
 to a grid point, the more effect it has on that grid point.  In `gnuplot`,
 this distance computation is optimized for norms that are powers of 2,
 specifically 1, 2, 4, 8, and 16, but any non-negative integer can be used.

 The `dgrid3d` option is a simple low pass filter that converts scattered data
 to a grid data set.  More sophisticated approaches to this problem exist and
 should be used to preprocess the data outside `gnuplot` if this simple
 solution is found inadequate.

 Examples:
        set dgrid3d 10,10,2
        set dgrid3d ,,4

 The first specifies that a grid of size 10 by 10 is to be constructed using
 the L2 norm (a norm of 2 is to be used in the distance computation).  The
 second only modifies the norm to be used to L4.
^ <a href=scatter/scatter.html> Dgrid3d Demo.</a>

3 dummy
?set dummy
?show dummy
?dummy
 The `set dummy` command changes the default dummy variable names.

 Syntax:
         set dummy <dummy-var>{,<dummy-var>}
         show dummy

 By default, `gnuplot` assumes that the independent variable for the `plot`
 command is x, and the independent variables for the `splot` command are x and
 y.  They are called the dummy variables because it is just a notation to
 indicate the independent variables.  It may be more convenient to call a
 dummy variable by a more physically meaningful or conventional name.  For
 example, when plotting time functions:

         set dummy t
         plot sin(t), cos(t)

 Examples:
         set dummy u,v
         set dummy ,s

 The second example sets the second variable to s.

 The `set parametric` command also changes the dummy variables (to t for
 `plot` and u,v for `splot`).
3 encoding
?set encoding
?show encoding
?encoding
 The `set encoding` command selects a character encoding.  Valid values are:
   `default`,    which does nothing;
   `iso_8859_1`, which is used on many Unix workstations and with MS-Windows;
   `cp437`,      the standard IBM PC character encoding and
   `cp850`,      the standard alternate IBM PC character encoding.

 Syntax:
         set encoding <value>
         show encoding

 Please note that this is not supported on all terminal types. Current
 terminals supperted are:
   postscript.
3 format
?set format
?show format
?format
 The format of the tic-mark labels can be set with the `set format` command.

 Syntax:
         set format {<axes>} {"<format-string>"}
         set format {<axes>} {'<format-string>'}
         show format

 where <axes> is either `x`, `y`, `z`, `xy`, `x2`, `y2` or nothing (which is
 the same as `xy`).  The length of the string representing a ticmark (after
 formatting with printf) is restricted to 100 characters.  If the format
 string is omitted, the format will be returned to the default "%g".  For
 LaTeX users, the format "$%g$" is often desirable.  If the empty string "" is
 used, no label will be plotted with each tic, though the tic mark will still
 be plotted.  To eliminate all tic marks, use `set noxtics` or `set noytics`.

 The default format for both axes is "%g", but other formats such as "%.2f" or
 "%3.0fm" are often desirable.  Anything accepted by printf when given a
 double precision number, and then accepted by the terminal, will work.  In
 particular, the formats f, e, and g will work, and the d, o, x, c, s, and u
 formats will not work.  If the data type for the axis is date/time, the
 format string must contain valid codes for the strftime function (outside of
 `gnuplot`, type `man strftime`).  It is best to stick to the conversion codes
 accepted by the `set timefmt` command.  If the format string looks like a
 floating point format, then `gnuplot` tries to construct a reasonable format.

 For `plot`, newline (\n) is accepted in the x-axis format string; for
 `splot`, newline is allowed for both x- and y-axis format strings.  Use
 double-quotes rather than single-quotes to enable such interpretation.  See
 also `syntax`.

 See also `set xtics` and `set ytics` for more control over tic labels.
3 function style
?set function style
?show function style
?function style
 The `set function style` command changes the default plotting style for
 function plots.

 Syntax:
         set function style <style-choice>
         show function style

 See `set style` for the choices.  If no choice is given, the choices are
 listed.  `show function style` shows the current default function plotting
 style.
3 functions
?show functions
 The `show functions` command lists all user-defined functions and their
 definitions.

 Syntax:
         show functions
^ <a href=spline/spline.html> Splines as User Defined Functions.</a>
^ <a href=airfoil/airfoil.html>Use of functions and complex variables for airfoils </a>
3 grid
?set grid
?show grid
?grid
 The `set grid` command allows grid lines to be drawn on the graph.

 Syntax:
         set grid {{no}{m}xtics} {{no}{m}ytics} {{no}{m}ztics} \
              {{no}{m}x2tics} {{no}{m}y2tics} \
              {polar {<angle>} {<major-linetype> {<minor-linetype>}}}
         show grid

 The grid can be enabled and disabled for the major and/or minor tic marks on
 any axis, and the linetype can be specified for major and minor grid lines.
 Additionally, a polar grid can be selected for 2-d plots---circles are drawn
 to intersect the selected tics, and radial lines are drawn at definable
 intervals.  (The interval is given in degrees or radians ,depending on the
 `set angles` setting.)  Note that a polar grid is no longer automatically
 generated in polar mode.

 The pertinent tics must be enabled before `set grid` can draw them; `gnuplot`
 will quietly ignore instructions to draw grid lines at non-existent tics, but
 they will appear if the tics are subsequently enabled.

 If no linetype is specified for the minor gridlines, the same linetype as the
 major gridlines is used.  The default polar angle is 30 degrees.

 Z grid lines are drawn on the back of the plot.  This looks better if a
 partial box is drawn around the plot---see `set border`.
3 hidden3d
?set hidden3d
?show hidden3d
 The `set hidden3d` command enables hidden line removal for explicit surface
 plotting (see `splot`).

 Syntax:
         set hidden3d
         set nohidden3d
         show hidden3d

 Hidden line removal may be used for both explicit functions and for explicit
 data.  It now works for parametric surfaces as well.  This mode is meaningful
 only when surfaces are `splot`ted `with lines`.

 When this flag is set, both the hidden portion of the surface and possibly
 its hidden contours (see `set contour`) as well as the hidden grid will be
 removed.  Each surface has its hidden parts removed with respect to itself
 and to other surfaces, if more than one surface is plotted.  But contours
 drawn on the surface (`set contour surface`) don't seem to work.  Labels and
 arrows are always visible and are unaffected.
^ <a href=hidden/hidden.html> Hidden Line Removal Demo</a> and
^ <a href=singulr/singulr.html> Complex Hidden Line Demo. </a>
3 isosamples
?set isosamples
?show isosamples
?isosamples
 The isoline density of surfaces may be changed by the `set isosamples`
 command.

 Syntax:
         set isosamples <iso_1> {,<iso_2>}
         show isosamples

 Each surface plot will have <iso_1> iso-u lines and <iso_2> iso-v lines.  If
 you only specify <iso_1>, <iso_2> will be set to the same value as <iso_1>.
 By default, sampling is set to 10 isolines per u or v axis.  A higher
 sampling rate will produce more accurate plots, but will take longer.  These
 parameters have no effect on data file plotting.

 An isoline is a curve parameterized by one of the surface parameters while
 the other surface parameter is fixed.  Isolines provide a simple means to
 display a surface.  By fixing the u parameter of surface s(u,v), the iso-u
 lines of the form c(v) = s(u0,v) are produced, and by fixing the v parameter,
 the iso-v lines of the form c(u) = s(u,v0) are produced.

 When a surface plot is being done without the removal of hidden lines, `set
 samples` also has an effect on the number of points being evaluated---it
 controls the number of points sampled along each isoline.  See `set samples`.
3 key
?set key
?set nokey
?show key
?key
 The `set key` enables a key describing curves on a plot.

 Syntax:
         set key { <position> | \
                  left | right | top | bottom | outside | below } \
                 { Left | Right } \
                 { {no}reverse } \
                 { title "<text>" } \
                 { {no}box {<linetype>} }
         set nokey
         show key

 By default the key is placed in the upper right corner of the plot.  The
 keywords `left`, `right`, `top`, `bottom`, `outside` and `below` may be used
 to place the key in the other corners inside the plot or to the right
 (outside) or below the plot.  They may be given alone or combined.

 Justification of the labels within the key is controlled by `Left` or `Right`
 (default is `Right`).  The text and sample can be reversed (`reverse`) and a
 box can be drawn around the key (`box {<linetype>}`) in a specified linetype.
 A title can be put on the key (`title "<text>"`)---see also `syntax` for the
 distinction between text in single- or double-quotes.  The title uses the
 same justification as do the individual labels.

 The <position> can be a simple x,y,z as in previous versions, but these can
 be preceded by one of four keywords (`first`, `second`, `graph`, `screen`)
 which selects the co-ordinate system in which the position is specified.  See
 `set co-ordinates` for more details.  The key is drawn as a sequence of
 lines, with one plot described on each line.  On the right-hand side (or the
 left-hand side, if `reverse` is selected) of each line is a representation
 that attempts to mimic the way the curve is plotted.  On the other side of
 each line is the text description, obtained from the `plot` command.  See
 `plot title` to change this description.  The lines are vertically arranged
 so that an imaginary straight line divides the left- and right-hand sides of
 the key.  It is the co-ordinates of this line that are specified with the
 `set key` command.  In a `plot`, only the x and y co-ordinates are used to
 specify the line position.  For a `splot`, x, y and z are all used as a 3-d
 location mapped using the same mapping as the plot itself to form the
 required 2-d screen position of the imaginary line.

 Some or all of the key may be outside of the plot boundary, although this may
 interfere with other labels and may cause an error on some devices.  If you
 use the keywords `outside` or `below`, `gnuplot` makes space for the keys and
 the plot becomes smaller.  Putting keys outside to the right, they occupy as
 few columns as possible, and putting them below, as many columns as possible
 (depending of the length of the labels), thus stealing as little space from
 the plot as possible.

 When using the TeX or PostScript drivers, or similar drivers where formatting
 information is embedded in the string, `gnuplot` is unable to calculate
 correctly the width of the string for key positioning.  If the key is to be
 positioned at the left, it may be convenient to use the combination  `set key
 left Left reverse`.  The box and gap in the grid will be the width of the
 literal string.

 If `splot` is being used to draw contours, the contour labels will be listed
 in the key.  If the alignment of these labels is poor or a different number
 of decimal places is desired, the label format can be specified.  See `set
 clabel` for details.

 Examples:

 This places the key at the default location:
         set key
 This disables the key:
         set nokey
 This places a key at co-ordinates 2,3.5,2:
         set key 2,3.5,2
 This places the key below the plot:
         set key below
 This places the key in the bottom left corner, left-justifies the text,
 gives it a title, and draws a box around it in linetype 3:
         set key left bottom Left title 'Legend' box 3
3 label
?set label
?set nolabel
?show label
?label
?nolabel
 Arbitrary labels can be placed on the plot using the `set label` command.

 Syntax:
          set label {<tag>} {"<label_text>"} {at <position>}
                            {<justification>} {font "<name><,size>"}
          set nolabel {<tag>}
          show label

 The <position> is specified by either x,y or x,y,z, and may be preceded by
 `first`, `second`, `graph`, or `screen` to select the co-ordinate system.
 See `set co-ordinates` for details.

 The text is scanned for backslash-octal (\nnn) conversion.  It defaults to
 the null text "".

 The tag is an integer that is used to identify the label. If no <tag> is
 given, the lowest unused tag value is assigned automatically.  The tag can be
 used to delete or modify a specific label.  To change any attribute of an
 existing label, use the `set label` command with the appropriate tag, and
 specify the parts of the label to be changed.

 By default, the text is placed flush left against the point x,y,z.  To adjust
 the way the label is positioned with respect to the point x,y,z, add the
 parameter <justification>, which may be `left`, `right` or `center`,
 indicating that the point is to be at the left, right or center of the text.
 Labels outside the plotted boundaries are permitted but may interfere with
 axis labels or other text.

 If one (or more) axis is timeseries, the appropriate co-ordinate should be
 given as a quoted time string according to the `timefmt` format string.  See
 `set {x,y,z}data` and `set timefmt`.

 The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify
 a newline.

 Examples:

 To set a label at (1,2) to "y=x", use:
          set label "y=x" at 1,2
 To set a label of the sign Sigma of size 24 at center of plot area, use:
          set label "S" at graph 1,2 font "Symbol,24"
 To set a label "y=x^2" with the right of the text at (2,3,4), and tag the
 label as number 3, use:
          set label 3 "y=x^2" at 2,3,4 right
 To change the preceding label to center justification, use:
          set label 3 center
 To delete label number 2, use:
          set nolabel 2
 To delete all labels, use:
          set nolabel
 To show all labels (in tag order), use:
          show label
 To set a label on a plot with a timeseries (timefmt="%d/%m/%y,%H:%M) on the
 x axis, use something like:
          set label "Harvest" at "25/8/93",1
3 lmargin
 The command `set lmargin` sets the size of the left margin.  Please see
 `set margins` for details.
3 logscale
?set logscale
?set nologscale
?show logscale
?logscale
?nologscale
 Log scaling may be set on the x, y, z, x2 and/or y2 axes.

 Syntax:
         set logscale <axes> <base>
         set nologscale <axes>
         show logscale

 where <axes> may be any combinations of `x`, `y`, and `z`, in any order, or
 `x2` or `y2` and where <base> is the base of the log scaling.  If <base> is
 not given, then 10 is assumed.  If <axes> is not given, then all axes are
 assumed.  `set nologscale` turns off log scaling for the specified axes.

 Examples:

 To enable log scaling in both x and z axes:
        set logscale xz
 To enable scaling log base 2 of the y axis:
        set logscale y 2
 To disable z axis log scaling:
        set nologscale z
3 missing
?set missing
?missing
 The `set missing` command allows you to tell `gnuplot` what character is
 used in a data file to denote missing data.

 Syntax:
         set missing {"character"}

 Example:
         set missing "?"

 would mean that, when plotting a file containing

         1 1
         2 ?
         3 2

 the middle line would be ignored.

 There is no default character for `missing`.
3 mx2tics
 Minor tic marks along the x2 axis are controlled by `set mx2tics`.  Please
 see `set mxtics`.
3 my2tics
 Minor tic marks along the y2 axis are controlled by `set my2tics`.  Please
 see `set mxtics`.
3 mapping
?set mapping
?show mapping
?mapping
 If data are provided to `splot` in spherical or cylindrical co-ordinates,
 the `set mapping` command should be used to instruct `gnuplot` how to
 interpret them.

 Syntax:
         set mapping { cartesian | spherical | cylindrical }

 For a spherical co-ordinate system, the data occupy two or three columns.
 The first two are interpreted as the polar and azimuthal angles theta and phi
 (in the units specified by `set angles`).  The radius r is taken from the
 third column if there is one, or is set to unity if there is no third column.
 The mapping is:

         x = r * cos( theta ) * cos( phi )
         y = r * sin( theta ) * cos( phi )
         z = r * sin( phi )

 For a cylindrical co-ordinate system, the data again occupy two or three
 columns.  The first two are interpreted as theta (in the units specified by
 `set angles`) and z.  The radius is either taken from the third column or set
 to unity, as in the spherical case.  The mapping is:

         x = r * cos( theta )
         y = r * sin( theta )
         z = z

 The effects of `mapping` can be duplicated with the `using` filter on the
 `splot` command, but `mapping` may be more convenient if many data files are
 to be processed.

 `mapping` has no affect on data file `plot`s.
^ <a href=world/world.html>Mapping Demos.</a>
3 margin
?set margin
?show margin
?margin
?set bmargin
?show bmargin
?bmargin
?set lmargin
?show lmargin
?lmargin
?set rmargin
?show rmargin
?rmargin
?set tmargin
?show tmargin
?tmargin
 Normally the margins of the plot are automatically calculated based on tics
 and axis labels.  These computed values can be overridden by the `set margin`
 commands.  `show margin` shows the current settings.

 Syntax:
         set bmargin {<margin>}
         set lmargin {<margin>}
         set rmargin {<margin>}
         set tmargin {<margin>}
         show margin

 The units of <margin> are character heights or widths, as appropriate.  A
 positive value always adds to the size of the margin.  Omitting it causes
 `gnuplot` to revert to the computed values.
3 multiplot
?set multiplot
?multiplot
?set nomultiplot
 The command `set multiplot` places `gnuplot` in the multiplot mode, in which
 several plots are placed on the same page, window, or screen.

 Syntax:
         set multiplot
         set nomultiplot

 For some terminals, no plot is displayed until the command `set nomultiplot`
 is given, which causes the entire page to be drawn and then returns `gnuplot`
 to its normal single-plot mode.  For other terminals, each separate `plot`
 command produces a plot.

 The commands `set origin` and `set size` must be used to correctly position
 each plot; see `set origin` and `set size` for details of their usage.

 Example:
         set size 0.7,0.7
         set origin 0.1,0.1
         set multiplot
         set size 0.4,0.4
         set origin 0.1,0.1
         plot sin(x)
         set size 0.2,0.2
         set origin 0.5,0.5
         plot cos(x)
         set nomultiplot

 displays a plot of cos(x) stacked above a plot of sin(x).  Note the initial
 `set size` and `set origin`.  While these are not always required, their
 inclusion is recommended.  Some terminal drivers require that bounding box
 information be available before any plots can be made, and the form given
 above guarantees that the bounding box will include the entire plot array
 rather than just the bounding box of the first plot.
3 mxtics
?set mxtics
?set nomxtics
?show mxtics
?mxtics
?nomxtics
?set mytics
?set nomytics
?show mytics
?mytics
?nomytics
?set mztics
?set nomztics
?show mztics
?mztics
?nomztics
?set mx2tics
?set nomx2tics
?show mx2tics
?mx2tics
?nomx2tics
?set my2tics
?set nomy2tics
?show my2tics
?my2tics
?nomy2tics
 Minor tic marks along the x axis are controlled by `set mx2tics`.  They can
 be turned off with `set nomxtics`.  Similar commands control minor tics along
 the other axes.

 Syntax:
         set mxtics {<freq>}
         set mytics {<freq>}
         set mztics {<freq>}
         set mx2tics {<freq>}
         set my2tics {<freq>}
         set nomxtics
         etc.
         show mxtics
         etc.

 <freq> is the number of sub-intervals (NOT the number of minor tics!) between
 major tics (ten is the default, so there are nine minor tics between major
 tics).

 If the axis is logarithmic, the number of sub-intervals will be set to a
 reasonable number by default (based upon the length of a decade).  This will
 be overridden if <freq> is given.  However the usual minor tics (2, 3, ...,
 8, 9 between 1 and 10, for example) are obtained by setting <freq> to 10,
 even though there are but nine sub-intervals.

 By default, minor tics are off for linear axes and on for logarithmic axes.
 They inherit the settings for `axis|border` and `{no}mirror` specified for
 the major tics.  Please see `set xtics` for information about these.
3 mytics
 Minor tic marks along the y axis are controlled by `set mytics`.  Please
 see `set mxtics`.
3 mztics
 Minor tic marks along the z axis are controlled by `set mztics`.  Please
 see `set mxtics`.
3 offsets
?set offsets
?noset offsets
?show offsets
?offsets
 Offsets provide a mechanism to put a boundary around the data inside of an
 autoscaled plot.

 Syntax:
         set offsets <left>, <right>, <top>, <bottom>
         set nooffsets
         show offsets

 Each offset may be a constant or an expression.  Each defaults to 0.  Left
 and right offsets are given in units of the x axis, top and bottom offsets in
 units of the y axis.  A positive offset expands the plot in the specified
 direction, e.g., a positive bottom offset makes ymin more negative.  Negative
 offsets, while permitted, can have unexpected interactions with autoscaling
 and clipping.

 Offsets are ignored in `splot`s.

 Example:
         set offsets 0, 0, 2, 2
         plot sin(x)

 This plot of sin(x) will have a y range [-3:3] because the function
 will be autoscaled to [-1:1] and the vertical offsets are each two.
3 origin
?set origin
?origin
 The `set origin` command is used to specify the origin of a plotting surface
 (i.e., the graph and its margins) on the screen.  The co-ordinates are given
 in the `screen` co-ordinate system (see `co-ordinates` for information about
 this system).

 Syntax:
         set origin <x-origin>,<y-origin>
3 output
?set output
?show output
?output
 By default, plots are displayed to the standard output. The `set output`
 command redirects the display to the specified file or device.

 Syntax:
         set output {"<filename>"}
         show output

 The filename must be enclosed in quotes.  If the filename is omitted, any
 output file opened by a previous invocation of `set output` will be closed
 and new output will be sent to the standard output.  MSDOS users should note
 that the \ character has special significance in double-quoted strings, so
 single-quotes should be used for filenames in different directories.

 On machines with popen functions (Unix), output can be piped through a shell
 command if the first character of the filename is '|'.  For instance,

         set output "|lpr -Plaser filename"
         set output "|lp -dlaser filename"

 On MSDOS machines, `set output "PRN"` will direct the output to the default
 printer.  On VMS, output can be sent directly to any spooled device.  It is
 also possible to send the output to DECnet transparent tasks, which allows
 some flexibility.
3 parametric
?set parametric
?set noparametric
?show parametric
?parametric
?noparametric
 The `set parametric` command changes the meaning of `plot` (`splot`) from
 normal functions to parametric functions.  The command `set noparametric`
 restores the plotting style to normal, single-valued expression plotting.

 Syntax:
         set parametric
         set noparametric
         show parametric

 For 2-d plotting, a parametric function is determined by a pair of parametric
 functions operating on a parameter.  An example of a 2-d parametric function
 would be `plot sin(t),cos(t)`, which draws a circle (if the aspect ratio is
 set correctly---see `set size`).  `gnuplot` will display an error message if
 both functions are not provided for a parametric `plot`.

 For 3-d plotting, the surface is described as x=f(u,v), y=g(u,v), z=h(u,v).
 Therefore a triplet of functions is required.  An example of a 3-d parametric
 function would be `cos(u)*cos(v),cos(u)*sin(v),sin(u)`, which draws a sphere.
 `gnuplot` will display an error message if all three functions are not
 provided for a parametric `splot`.

 The total set of possible plots is a superset of the simple f(x) style plots,
 since the two functions can describe the x and y values to be computed
 separately.  In fact, plots of the type t,f(t) are equivalent to those
 produced with f(x) because the x values are computed using the identity
 function.  Similarly, 3-d plots of the type u,v,f(u,v) are equivalent to
 f(x,y).

 Note that the order the parametric functions are specified is xfunction,
 yfunction (and zfunction) and that each operates over the common parametric
 domain.

 Also, the `set parametric` function implies a new range of values.  Whereas
 the normal f(x) and f(x,y) style plotting assume an xrange and yrange (and
 zrange), the parametric mode additionally specifies a trange, urange, and
 vrange.  These ranges may be set directly with `set trange`, `set urange`,
 and `set vrange`, or by specifying the range on the `plot` or `splot`
 commands.  Currently the default range for these parametric variables is
 [-5:5].  Setting the ranges to something more meaningful is expected.
3 pointsize
?set pointsize
?show pointsize
?pointsize
 The `set pointsize` command changes the size of the points used in plots.

 Syntax:
         set pointsize <pointsize>
         show pointsize

 Default is pointsize 1.0.  Larger pointsizes (>1.0) are useful for high
 resolution in bitmapped graphics.

 Please note that the pointsize setting is not supported with all terminal
 types.
3 polar
?set polar
?set nopolar
?show polar
?polar
?nopolar
 The `set polar` command changes the meaning of the plot from rectangular
 co-ordinates to polar co-ordinates.

 Syntax:
         set polar
         set nopolar
         show polar

 There have been changes made to polar mode in version 3.6, so that scripts
 for `gnuplot` versions 3.5 and earlier will require modification.  The main
 change is that the dummy variable t is used for the angle so that the x and
 y ranges can be controlled independently.  Other changes are:
 1) tics are no longer put along the zero axes automatically
 ---use `set [x|y]tics axis nomirror`;
 2) the grid, if selected, is not automatically polar
 ---use `set grid polar`;
 3) the grid is not labelled with angles
 ---use `set label` as necessary.

 In polar co-ordinates, the dummy variable (t) is an angle.  The default range
 of t is [0:2*pi], or, if degree units have been selected, to [0:360] (see
 `set angles`).

 The command `set nopolar` changes the meaning of the plot back to the default
 rectangular co-ordinate system.

 The `set polar` command is not supported for `splot`s.  See the `set mapping`
 command for similar functionality for `splot`s.

 While in polar co-ordinates the meaning of an expression in t is really
 r = f(t), where t is an angle of rotation.  The trange controls the domain
 (the angle) of the function, and the x and y ranges control the range of the
 plot in the x and y directions.

 Example:
         set polar
         plot t*sin(t)
         plot [-2*pi:2*pi] [-3:3] [-3:3] t*sin(t)

 The first `plot` uses the default polar angular domain of 0 to 2*pi.  The
 radius and the size of the plot are scaled automatically.  The second `plot`
 expands the domain, and restricts the size of the plot to [-3:3] in both
 directions.

 You may want to `set size square` to have `gnuplot` try to make the aspect
 ratio equal to unity, so that circles look circular.
^ <a href=polar/polar.html>Polar demos </a>
^ <a href=poldat/poldat.html>Polar Data Plot. </a>
3 range
?set xrange
?show xrange
?xrange
?set yrange
?show yrange
?yrange
?set zrange
?show zrange
?zrange
?set x2range
?show x2range
?x2range
?set y2range
?show y2range
?y2range
?set rrange
?show rrange
?rrange
?set trange
?show trange
?trange
?set urange
?show urange
?urange
?set vrange
?show vrange
?vrange
 The `set xrange` command sets the horizontal range that will be displayed.
 A similar command exists for each of the other axes, as well as for the
 polar radius r and the parametric variables t, u, and v.

 Syntax:
         set xrange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set xrange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set zrange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set x2range [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set y2range [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set rrange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set trange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set urange [{<min> : <max>}] {{no}reverse} {{no}writeback}
         set vrange [{<min> : <max>}] {{no}reverse} {{no}writeback}

 where <min> and <max> terms are constants or expressions or a star to set
 autoscaling.  If the data are date/time, you must give the range as a quoted
 string according to the `set timefmt` format.  Both the <min> and <max>
 terms are optional.  Any value omitted will not be changed.

 The `reverse` option reverses the direction of the axis, e.g., `set xrange
 [0:1] reverse` will produce an axis with 1 on the left and 0 on the right.
 This is identical to the axis produced by `set xrange [1:0]`, of course.
 `reverse` is intended primarily for use with `autoscale`.

 The `writeback` option essentially saves the range found by `autoscale` in
 the min/max buffers that would be filled by `set range`.  This is useful if
 you wish to plot several functions together but have the range determined by
 only some of them.  The `writeback` operation is performed during the `plot`
 execution, so it must be specified before that command.  For example,

         set xrange [-10:10]
         set yrange [] writeback
         plot sin(x)
         set noautoscale y
         replot x/2

 results in a yrange of [-1:1] as found only from the range of sin(x); the
 [-5:5] range of x/2 is ignored.  Executing `show yrange` after each command
 in the above example should help you understand what is going on.

 In 2-d, `xrange` and `yrange` determine the extent of the axes, `trange`
 determines the range of the parametric variable in parametric mode or the
 range of the angle in polar mode.  Similarly in parametric 3-d, `xrange`,
 `yrange`, and `zrange` govern the axes and `urange` and `vrange` govern the
 parametric variables.  In polar mode,`rrange` determines the radial range
 plotted.  <rmin> acts as an additive constant to the radius, whereas <rmax>
 acts as a clip to the radius---no point with radius greater than <rmax> will
 be plotted.

 Any range may be partially or totally autoscaled, although it may not make
 sense to autoscale a parametric variable unless it is plotted with data.

 Ranges may also be specified on the `plot` command line.  A range given on
 the plot line will be used for that single `plot` command; a range given by
 a `set` command will be used for all subsequent plots that do not specify
 their own ranges.  The same holds true for `splot`.

 Examples:
 To set the xrange to the default:
         set xrange [-10:10]
 To set the yrange to increase downwards:
         set yrange [10:-10]
 To change zmax to 10 without affecting zmin (which may still be autoscaled):
         set zrange [:10]
 To autoscale xmin while leaving xmax unchanged:
         set xrange [*:]
3 rmargin
 The command `set rmargin` sets the size of the right margin.  Please see
 `set margins` for details.
3 rrange
?set rrange
?show rrange
?rrange
 For a polar plot, the radial co-ordinate should be non-negative, but `rrange`
 can be used to move the singularity.

 Syntax:
         set rrange {[<rmin>:<rmax>]}
         show rrange

 `rmin` specifies the radius at the origin and `rmax` provides clipping for
 large radii.  `xrange` and `yrange` are affected---the ranges can be set as
 if the plot was of r(t)-rmin, with rmin added to all the labels.  (`set term
 table` reveals that it is in fact implemented that way.)
3 samples
?set samples
?show samples
?samples
 The sampling rate of functions may be changed by the `set samples` command.

 Syntax:
         set samples <samples_1> {,<samples_2>}
         show samples

 By default, sampling is set to 100 points.  A higher sampling rate will
 produce more accurate plots, but will take longer.  This parameter no longer
 has any effect on data-file plotting.

 When a 2-d plot is being done, only the value of <samples_1> is relevant.

 When a surface plot is being done without the removal of hidden lines, the
 value of samples specifies the number of samples that are to be evaluated for
 isoline.  Each iso-v line will have <sample_1> samples and each iso-u line
 will have <sample_2> samples.  If you only specify <samples_1>, <samples_2>
 will be set to the same value as <samples_1>.  See also `set isosamples`.
3 size
?set size
?show size
?size
 The `set size` command scales the displayed size of the plot.

 Syntax:
         set size {{no}square} {<xscale>,<yscale>}
         show size

 The <xscale> and <yscale> values are the scaling factors for the size.  The
 defaults (1,1) are selected if the scaling factors are omitted.  If `square`
 is specified, `gnuplot` will attempt to make the plot area square, to give
 polar plots the correct aspect ratio, for example.  Success depends on the
 terminal driver selected.  The plot area will be the largest square that will
 fit into the specified portion of the output.

 Note that the size of the plot includes the space used by the labels; the
 plotting area itself is smaller.  `square` takes only the plotting area into
 account.

 If `set key out` is specified, the key is drawn at the far right edge of the
 usable area---you can use something like
    `set size square 0.9,1`
 to bring it closer to the square plotting area.

 On some terminals, changing the size of the plot will result in text being
 misplaced.  Increasing the size of the plot may produce strange results.
 Decreasing is safer.

 Examples:

 To set the size to normal size use:
         set size 1,1
 To make the plot half size and square use:
         set size square 0.5,0.5
 To show the size use:
         show size

 For the LaTeX and Fig terminals the default size (scale factor 1,1) is 5
 inches wide by 3 inches high.  The big Fig terminal (`bfig`) is 7 inches wide
 by 5 inches high.  The PostScript default is landscape mode 10 inches wide
 and 7 inches high; portrait mode has these dimensions reversed, and EPS cuts
 them in half.
3 style
?set style
?show style
 Default styles are chosen with the `set function style` and `set data style`
 commands.  See `plot style` for information about how to override the default
 plotting style for individual functions and data sets.

 Syntax:
         set function style <style>
         set data style <style>
         show function style
         show data style

 The types used for all line and point styles (i.e., solid, dash-dot, color,
 etc. for lines; circles, squares, crosses, etc. for points) will be either
 those specified on the `plot` or `splot` command or will be chosen
 sequentially from the types available to the terminal in use.  Use the
 command `test` to see what is available.

 None of the `errorbars` styles can be used with `splot`s or function `plot`s.
 If one is specified, it will be changed to `points`.

 For 2-d data with more than two columns, `gnuplot` is picky about the allowed
 `errorbar` styles:

 For three columns, only `xerrorbars`, `yerrorbars` (or `errorbars`), `boxes`,
 and `boxerrorbars` are allowed.  If another plot style is used, the style
 will be changed to `yerrorbars`.  The `boxerrorbars` style will calculate the
 boxwidth automatically.

 For four columns, only `xerrorbars`, `yerrorbars` (or `errorbars`),
 `xyerrorbars`, `boxxyerrorbars`, and `boxerrorbars`, are allowed.  An illegal
 plot style will be changed to `yerrorbars`.

 Five-column data allow only the `boxerrorbars` style.  An illegal style will
 be changed to `boxerrorbars` before plotting.

 Six- and seven-column data only allow the `xyerrorbars` and `boxxyerrorbars`
 styles.  Illegal styles will be changed to `xyerrorbars` before plotting.

 Use the `using` option on the `plot` command to set up the correct number of
 columns for the style you want.
4 bezier
?set style bezier
?style bezier
?bezier
 The `bezier` style connects adjacent points with Bezier curves.
4 boxerrorbars
?set style boxerrorbars
?style boxerrorbars
?boxerrorbars
 The `boxerrorbars` style is only relevant to 2-d data plotting.  It is a
 combination of the `boxes` and `yerrorbars` styles.  The boxwidth will come
 from the fourth column if the y errors are in the form of "ydelta" and the
 boxwidth was not previously set equal to -2.0 (`set boxwidth -2.0`) or from
 the fifth column if the y errors are in the form of "ylow yhigh".  The
 special case  `boxwidth = -2.0` is for four-column data with y errors in the
 form "ylow yhigh".  In this case the boxwidth will be calculated so that each
 box touches the adjacent boxes.  The width will also be calculated in cases
 where three-column data are used.

 The box height is determined from the y error in the same way as it is for
 the `yerrorbars` style---either from y-ydelta to y+ydelta or from ylow to
 yhigh, depending on how many data columns are provided.
4 boxes
?set style boxes
?style boxes
?boxes
?set style bargraph
?style bargraph
?bargraph
 The `boxes` style is only relevant to 2-d plotting.  It draws a box centered
 about the given x co-ordinate from the x axis (not the plot border) to the
 given y co-ordinate.  The width of the box is obtained in one of three ways.
 If it is a data plot and the data file has a third column, this will be used
 to set the width of the box.  If not, if a width has been set using the `set
 boxwidth` command, this will be used.  If neither of these is available, the
 width of each box will be calculated automatically so that it touches the
 adjacent boxes.
4 boxxyerrorbars
?set style boxxyerrorbars
?style boxxyerrorbars
?boxxyerrorbars
 The `boxxyerrorbars` style is only relevant to 2-d data plotting.  It is a
 combination of the `boxes` and `xyerrorbars` styles.

 The box width and height are determined from the x and y errors in the same
 way as they are for the `xyerrorbars` style---either from xlow to xhigh and
 from ylow to yhigh, or from x-xdelta to x+xdelta and from y-ydelta to
 y+ydelta , depending on how many data columns are provided.
4 csplines
?set style csplines
?style csplines
?csplines
 The `csplines` style connects adjacent points with cubic splines.
4 dots
?set style dots
?style dots
?dots
 The `dots` style plots a tiny dot at each point; this is useful for scatter
 plots with many points.
4 fsteps
?set style fsteps
?style fsteps
?fsteps
 The `fsteps` style is only relevant to 2-d plotting.  It connects consecutive
 points with two line segments: the first from (x1,y1) to (x1,y2) and the
 second from (x1,y2) to (x2,y2).
4 impulses
?set style impulses
?style impulses
?impulses
 The `impulses` style displays a vertical line from the x axis (not the plot
 border), or from the grid base for `splot`, to each point.
4 lines
?set style lines
?style lines
?lines
 The `lines` style connects adjacent points with straight line segments.
4 linespoints
?set style linespoints
?style linespoints
?linespoints
 The `linespoints` style does both `lines` and `points`, that is, it draws a
 small symbol at each point and then connects adjacent points with straight
 line segments.  The command `set pointsize` may be used to change the size of
 the points.  See `set pointsize` for its usage.
4 points
?set style points
?style points
?points
 The `points` style displays a small symbol at each point.  The command `set
 pointsize` may be used to change the size of the points.  See `set pointsize`
 for its usage.
4 sbezier
?set style sbezier
?style sbezier
?sbezier
 The `sbezier` style connects adjacent points with Bezier curves different in
 some way from those used by the `bezier` style.
4 splines
?set style splines
?style splines
?splines
 The `splines` style connects adjacent points with quadratic splines.
4 steps
?set style steps
?style steps
?steps
 The `steps` style is only relevant to 2-d plotting.  It connects consecutive
 points with two line segments: the first from (x1,y1) to (x2,y1) and the
 second from (x2,y1) to (x2,y2).
4 vectors
?set style vectors
?style vectors
?vectors
 The `vectors` style draws a vector from (x,y) to (x+xdelta,y+ydelta).  Thus
 it requires four columns of data.  It also draws a small arrowhead at the
 end of the vector.

 The `vectors` style is still experimental: it doesn't get clipped properly
 and other things may also be wrong with it.  Use it at your own risk.
4 xerrorbars
?set style xerrorbars
?style xerrorbars
?xerrorbars
 The `xerrorbars` style is only relevant to 2-d data plots.  `xerrorbars` is
 like `dots`, except that a horizontal error bar is also drawn.  At each point
 (x,y), a line is drawn from (xlow,y) to (xhigh,y) or from (x-xdelta,y) to
 (x+xdelta,y), depending on how many data columns are provided.  A tic mark
 is placed at the ends of the error bar (unless `set bar small` is used).
4 xyerrorbars
?set style xyerrorbars
?style xyerrorbars
?xyerrorbars
 The `xyerrorbars` style is only relevant to 2-d data plots.  `xyerrorbars` is
 like `dots`, except that horizontal and vertical error bars are also drawn.
 At each point (x,y), lines are drawn from (x,y-ydelta) to (x,y+ydelta) and
 from (x-xdelta,y) to (x+xdelta,y) or from (x,ylow) to (x,yhigh) and from
 (xlow,y) to (xhigh,y), depending upon the number of data columns provided.  A
 tic mark is placed at the ends of the error bar (unless `set bar small` is
 used).

 If data are provided in an unsupported mixed form, the `using` filter on the
 `plot` command should be used to set up the appropriate form.  For example,
 if the data are of the form (x,y,xdelta,ylow,yhigh), then you can use

        plot 'data' using 1:2:($1-$3),($1+$3),4,5 with xyerrorbars
4 yerrorbars
?set style yerrorbars
?style yerrorbars
?yerrorbars
?set style errorbars
?style errorbars
?errorbars
 The `yerrorbars` (or `errorbars`) style is only relevant to 2-d data plots.
 `yerrorbars` is like `dots`, except that a vertical error bar is also drawn.
 At each point (x,y), a line is drawn from (x,y-ydelta) to (x,y+ydelta) or
 from (x,ylow) to (x,yhigh), depending on how many data columns are provided.
 A tic mark is placed at the ends of the error bar (unless `set bar small` is
 used).
3 surface
?set surface
?set nosurface
?show surface
?surface
 The command `set surface` controls the display of surfaces, which are drawn
 as a mesh of isolines.

 Syntax:
         set surface
         set nosurface
         show surface

 Whenever `set nosurface` is issued, no surface isolines/mesh will be drawn.
 This is useful if contours are to be displayed by themselves.  See also `set
 contour`.
3 terminal
?set terminal
?show terminal
?terminal
 `gnuplot` supports many different graphics devices.  Use the `set terminal`
 command to select the type of device for which `gnuplot` will produce output.

 Syntax:
         set terminal {<terminal-type>}
         show terminal

 If <terminal-type> is omitted, `gnuplot` will list the available terminal
 types.  <terminal-type> may be abbreviated.

 Use `set output` to redirect this output to a file or device.

 Several terminals have additional options.  For example, see `dumb`,
 `iris4d`, `hpljii` or `postscript`.
3 - paste here the help from the .trm files, at level 4 onwards
4 atari ST (via AES)
?set terminal atari
?atari
 The `atari` terminal has options to set the character size and the screen
 colors.  The driver expects a space-separated list containing the character
 size and up to 16 three-digit hex numbers, where each digit represents RED,
 GREEN and BLUE (in that order).  The range of 0--15 is scaled to whatever
 color range the screen actually has.  On a normal ST screen, odd and even
 intensities are the same.

 Examples:

        set terminal atari 4 # (use small (6x6) font)
        set terminal atari 6 0 # (set monochrome screen to white on black)
        set terminal atari 13 0 fff f00 f0 f ff f0f ff0
        # (set first eight colors to black, white, green, blue, cyan, \
          purple, and yellow and use large font (8x16).)

 Additionally, if an environment variable GNUCOLORS exists, its contents are
 interpreted as an options string, but an explicit terminal option takes
 precedence.
4 atari ST (via VDI)
?set terminal vdi
?vdi
 This terminal is the same as the `atari` terminal, except for the fact that
 it sends output to the screen via the VDI and not into AES-Windows.)

 The `vdi` terminal has the same options as the `atari` terminal.

4 atari ST (for Multitasking Systems)
?set terminal mtos
?mtos
 The `mtos` terminal has no options.  It sends data via a pipe to an external
 program called GPCLIENT.  It runs under MiNT, MULTITOS and Magic 3.x.
4 epson
?set terminal epson
?set terminal epson180
?set terminal epson60
?set terminal starc
?set terminal tandy60
?epson
 This set of drivers support Epson printers and derivatives.  `epson` is a
 generic 9-wire printer with a resolution of 512x384.  `starc` is a Star Color
 printer with the same resolution.  `epson180` and `epson60` are 180-dpi and
 60-dpi drivers for newer 24-wire printers.  This also includes bubble jet
 printers.  Their resolutions are 1260x1080 and 480x360, respectively.  The
 `tandy60` is identical to the `epson60` driver with one additional escape
 sequence to start IBM mode.

 With all of these drivers, a binary copy is required on a PC to print.  Do
 not use `print`:

        copy file /b lpt1:
4 gpic
?set terminal gpic
?gpic
 This driver is only known to work with the Free Software Foundation
 gpic/groff package.  Modification for the Document Workbench pic/troff
 package would be appreciated.  FSF gpic can also produce TeX output.

 A simple graph can be formatted using

      groff -p -mpic -Tps file.pic > file.ps.

 The output from pic can be pipe-lined into eqn, so it is possible to put
 complex functions in a graph with the set label and set {x/y}label commands.
 For instance,

    set ylab '@space 0 int from 0 to x alpha ( t ) roman d t@'

 will label the y axis with a nice integral if formatted with the command:

    gpic filename.pic | geqn -d@@ -Tps | groff -m[macro-package] -Tps
         > filename.ps

 Figures made this way can be scaled to fit into a document.  The pic language
 is easy to understand, so the graphs can be edited by hand if need be.  All
 co-ordinates in the pic-file produced by `gnuplot` are given as x+gnuplotx
 and y+gnuploty.  By default x and y are given the value 0.  If this line is
 removed with an editor in a number of files, one can put several graphs in
 one figure like this (default size is 5.0x3.0 inches):

    .PS 8.0
    x=0;y=3
    copy "figa.pic"
    x=5;y=3
    copy "figb.pic"
    x=0;y=0
    copy "figc.pic"
    x=5;y=0
    copy "figd.pic"
    .PE

 This will produce an 8-inch-wide figure with four graphs in two rows on top
 of each other.

 One can also achieve the same thing by the command

   set term pic x y

 For example, using

   .PS 6.0
   copy "trig.pic"
   .PE
4 hpljii
?set terminal hpljii
?hpljii
 The HP LaserJet II and HP DeskJet drivers have a single option.

 Syntax:
         set terminal hpljii {<resolution>}
         set terminal hpdj   {<resolution>}

 where <resolution> is the resolution of the output in dots per inch.  It must
 be `75`, `100`, `150` or `300`.  Note: there must be enough memory available
 to rasterize at the higher resolutions.

 Example:
         set terminal hpljii 150
4 imagen
?set terminal imagen
?imagen
 The imagen driver is able to draw several plots on each page (in either
 portrait or landscape orientation), and fontsize may also be specified.

 Options are:
       portrait
       landscape        (default)
       [ x , y ]        (where x and y are the number of plots in the x and y
                         directions on the page)
       n                (where n is fontsize in points)

 To plot 6 plots per page in two columns in portrait orientation:
       set term imagen po [2,3]

4 iris4d
?set terminal iris4d
?iris4d
 The iris4d driver can operate in two modes.

 Syntax:
         set terminal iris4d {24}

 If the hardware supports only 8 bits, use the default `set terminal iris4d`.
 If, however, the hardware supports 24 bits (8 per red/green/blue), use `set
 terminal iris4d 24`.

 When using 24-bit mode, the colors can be directly specified via the file
 .gnuplot_iris4d that is searched in the current directory and then in the
 home directory specified by the HOME environment variable.  This file holds
 RGB values for the background, border, labels and nine plotting colors, in
 that order.  For example, here is a file containing the default colors:

         85   85   85     /* Background */
         0    0    0      /* Boundary */
         170  0    170    /* Labeling */
         85   255  255    /* Plot Color 1 */
         170  0    0      /* Plot Color 2 */
         0    170  0      /* Plot Color 3 */
         255  85   255    /* Plot Color 4 */
         255  255  85     /* Plot Color 5 */
         255  85   85     /* Plot Color 6 */
         85   255  85     /* Plot Color 7 */
         0    170  170    /* Plot Color 8 */
         170  170  0      /* Plot Color 9 */

 This file has exactly 12 lines of RGB triples.  No empty lines are allowed
 and anything after the third number in line is ignored.
4 nec-cp6
?set terminal nec-cp6
?nec-cp6
 One option may be set in the nec-cp6 driver.  The resolution of this driver
 is 400x320.

 Syntax:
         set terminal nec-cp6 monochrome
         set terminal nec-cp6 color
         set terminal nec-cp6 draft
4 pcl5
?set terminal pcl5
?pcl5
 Three options may be set in the pcl5 driver.  The driver actually uses HPGL-2
 but there is a name conflict among the terminal devices.

 Syntax:
         set terminal pcl5 {<mode>} {<font>} {<fontsize>}

 where <mode> is `landscape`, or `portrait`, <font> is `stick`, `univers`, or
 `cg_times`, and fontsize is the size in points.

 Example:
         set terminal pcl5 landscape

4 tgif
?set terminal tgif
?tgif
 The Tgif driver supports different pointsizes (with `set pointsize`),
 different label fonts and font sizes (e.g. `set label "Hallo" at x,y font
 "Helvetica,34"`) and multiple plots on the page.  The proportions of the axes
 are not changed.

 Syntax:
         set terminal tgif {<mode>} {<[x,y]>} {<dashed>} \
                           {"<fontname>"} {<fontsize>}

 where <mode> is `portrait` or `landscape`, <[x,y]> specifies the number of
 plots in the x and y directions on the page, <dashed> is either `solid` or
 `dashed`, "<fontname>" is the name of a valid PostScript font, and <fontsize>
 specifies the size of the PostScript font.  Defaults are `portrait`, `[1,1]`,
 `dashed`, `"Helvetica"`, and `18`.

 The `solid` option is usually prefered if lines are colored, as they often
 are in the editor.  Hardcopy will be black-and-white, so `dashed` should be
 chosen for that.

 Multiplot is implemented in two different manners.

 The first multiplot implementation is the standard gnuplot multiplot feature:

   set term tgif
   set output "file.obj"
   set multiplot
   set origin x01,y01
   set size  xs,ys
   plot ...
        ...
   set origin x02,y02
   plot ...
   set nomultiplot

 See `set multiplot` for further information.

 The second version is the [x,y] option for the driver itself.  The advantage
 of this implementation is that everything is scaled and placed automatically
 without the need for setting origins and sizes; the plots keep their natural
 x/y proportions of 3/2 (or whatever is fixed by `set size`).

 If both multiplot methods are selected, the standard method is chosen and a
 warning message appears.

 Examples of single plots (or standard multiplot):
         set term tgif                  # -> portrait
         set term tgif "Times-Roman" 24 # -> Times-Roman font of size 24
         set term tgif landscape        # -> landscape
         set term tgif landscape solid  # -> landscape and solid lines

 Examples using the built-in multiplot mechanism:
         set term tgif portrait [2,4]   # -> 2 plots in x and 4 in y-direction
         set term tgif [1,2]            # -> 1 plot  in x and 2 in y-direction
         set term tgif landscape [3,3]  # -> landscape, with 3 plots in both
                                        #    x- and  y-directions
4 uniplex
?set terminal uniplex
?uniplex
 The uniplex driver is able to combine several plots in one image.  The option
 portrait causes the image to be drawn in a window where the width is about
 2/3 of the height (default is landscape---the image height is about 2/3 of
 the width).  The fontsize may also be specified (sizes 1--8).  Only one image
 is allowed per file.  If an 'X' is included in the `set output` filename, the
 'X' is replaced by a sequential plot number.

 Options are:
       portrait
       landscape        (default)
       [ x , y ]        (where x and y are the number of plots in the x and y
                         directions of the image)
       n                (where n is fontsize (1--8))

 To plot 6 plots in one image in two columns in portrait orientation:
       set term uniplex po [2,3]
4 windows
?set terminal windows
?windows
 Three options may be set in the windows driver.

 Syntax:
         set terminal windows {<color>} {"<fontname>"} {<fontsize>}

 `<color>` is either `color` or `monochrome`, `"<fontname>"` is the name of a
 valid Windows font, and `<fontsize>` is the size of the font in points.
5 graph-menu
?set terminal windows graph-menu
?graph-menu
 The `gnuplot graph` window has the following options on a pop-up menu
 accessed by pressing the right mouse button or selecting `Options` from the
 system menu:

 `Bring to Top` when checked brings the graph window to the top after every
 plot.

 `Color` when checked enables color linestyles.  When unchecked it forces
 monochrome linestyles.

 `Copy to Clipboard` copies a bitmap and a Metafile picture.

 `Background...` sets the window background color.

 `Choose Font...` selects the font used in the graphics window.

 `Line Styles...` allows customization of the line colors and styles.

 `Print...` prints the graphics windows using a Windows printer driver and
 allows selection of the printer and scaling of the output.  The output
 produced by `Print` is not as good as that from `gnuplot`'s own printer
 drivers.

 `Update wgnuplot.ini` saves the current window locations, window sizes, text
 window font, text window font size, graph window font, graph window font
 size, background color and linestyles to the initialization file
 `WGNUPLOT.INI`.
5 printing
?set terminal windows printing
?printing
 In order of preference, graphs may be be printed in the following ways.

 `1.` Use the `gnuplot` command `set terminal` to select a printer and `set
 output` to redirect output to a file.

 `2.` Select the `Print...` command from the `gnuplot graph` window.  An extra
 command `screendump` does this from the text window.

 `3.` If `set output "PRN"` is used, output will go to a temporary file.  When
 you exit from `gnuplot` or when you change the output with another `set
 output` command, a dialog box will appear for you to select a printer port.
 If you choose OK, the output will be printed on the selected port, passing
 unmodified through the print manager.  It is possible to accidentally (or
 deliberately) send printer output meant for one printer to an incompatible
 printer.
5 text-menu
?set terminal windows text-menu
?text-menu
 The `gnuplot text` window has the following options on a pop-up menu accessed
 by pressing the right mouse button or selecting `Options` from the system
 menu:

 `Copy to Clipboard` copies marked text to the clipboard.

 `Paste` copies text from the clipboard as if typed by the user.

 `Choose Font...` selects the font used in the text window.

 `System Colors` when selected makes the text window honor the System Colors
 set using the Control Panel.  When unselected, text is black or blue on a
 white background.

 `Update wgnuplot.ini` saves the current text window location, text window
 size, text window font and text window font size to the initialisation file
 `WGNUPLOT.INI`.

 `MENU BAR`

 If the menu file `WGNUPLOT.MNU` is found in the same directory as
 WGNUPLOT.EXE, then the menu specified in `WGNUPLOT.MNU` will be loaded.

 Menu commands are:
   [Menu]       Start a new menu with the name on the following line
   [EndMenu]    End current menu.
   --           Insert a horizontal menu separator
   |            Insert a vertical menu separator
   [Button]     Put next macro on a push button instead of a menu.

 Macros take two lines with the macro name (menu entry) on the first line and
 the macro on the second line.  Leading spaces are ignored.

 Macros commands are:
   [INPUT]      Input string with prompt terminated by [EOS] or {ENTER}
   [EOS]        End Of String terminator.  Generates no output.
   [OPEN]       Get name of file to open from list box, with title of list box
                terminated by [EOS], followed by default filename terminated
                by [EOS] or {ENTER}.  This uses COMMDLG.DLL from Windows 3.1.
   [SAVE]       Get name of file to save.  Similar to [OPEN]

 Macros character substitutions are:
   {ENTER}      Carriage Return '\r'
   {TAB}        Tab     '\011'
   {ESC}        Escape  '\033'
   {^A}         '\001'
   ...
   {^_}         '\031'

 Macros are limited to 256 characters after expansion.
5 wgnuplot.ini
?set terminal windows wgnuplot.ini
?wgnuplot.ini
 Windows `gnuplot` will read some of its options from the `[WGNUPLOT]` section
 of `WGNUPLOT.INI` in the Windows directory.  An example `WGNUPLOT.INI` file
 is shown below.

  [WGNUPLOT]
  TextOrigin=0 0
  TextSize=640 150
  TextFont=Terminal,9
  GraphOrigin=0 150
  GraphSize=640 330
  GraphFont=Arial,10
  GraphColor=1
  GraphToTop=1
  GraphBackground=255 255 255
  Border=0 0 0 0 0
  Axis=192 192 192 2 2
  Line1=0 0 255 0 0
  Line2=0 255 0 0 1
  Line3=255 0 0 0 2
  Line4=255 0 255 0 3
  Line5=0 0 128 0 4

 The `GraphFont` entry specifies the font name and size in points.  The five
 numbers given in the `Border`, `Axis` and `Line` entries are the `Red`
 intensity (0--255), `Green` intensity, `Blue` intensity, `Color Linestyle`
 and `Mono Linestyle`.  `Linestyles` are 0=SOLID, 1=DASH, 2=DOT, 3=DASHDOT,
 4=DASHDOTDOT.  In the example `WGNUPLOT.INI` file above, Line 2 is a green
 solid line in color mode, or a dashed line in monochrome mode.  The default
 line width is 1 pixel.  If `Linestyle` is negative, it specifies the width of
 a SOLID line in pixels.  Line1 and any linestyle used with the `points` style
 must be SOLID with unit width.
5 windows3.0
?set terminal windows windows3.0
?windows3.0
 Windows 3.1 is preferred, but WGNUPLOT will run under Windows 3.0 with the
 following restrictions:

 `1.` COMMDLG.DLL and SHELL.DLL (available with Windows 3.1 or Borland C++
 3.1) must be in the windows directory.

 `2.` WGNUPLOT.HLP produced by Borland C++ 3.1 is in Windows 3.1 format.
 You need to use the WINHELP.EXE supplied with Borland C++ 3.1.

 `3.` It won't run in real mode due to lack of memory.

 `4.` TrueType fonts are not available in the graph window.

 `5.` Drag-drop does not work.
3 tics
?set tics
?show tics
?tics
 The `set tics` command can be used to change the tics to be drawn outwards.

 Syntax:
         set tics {<direction>}
         show tics

 where <direction> may be `in` or `out`.  `set tics` defaults to `in`.  `show
 tics` displays a lot of information about the tics.

 It is now necessary to do
   set xtics nomirror ; set ytics nomirror
 in order to switch off the duplicate tics on top and right borders.  This is
 useful when doing impulse plots.

 See also the `set xtics`, `set ytics`, and `set ztics` commands for more
 control of tic marks and `set mxtics`, `set mytics`, and `set mztics` for
 minor tic marks.
3 ticslevel
?set ticslevel
?show ticslevel
?ticslevel
 Using `splot`, one can adjust the relative height of the vertical (Z) axis
 using `set ticslevel`.  The numeric argument provided specifies the location
 of the bottom of the scale.  A zero will put it on the bottom grid and any
 positive number somewhere along the z axis.

 Syntax:
         set ticslevel {<level>}
         show tics

 where <level> is a non-negative numeric argument.  For example,

         set ticslevel 0.5

 sets the tics level to the default value.

 See also `set view`.
3 ticscale
?set ticscale
?ticscale
 The size of the tic marks can be adjusted with `set ticscale`.

 Syntax:
         set ticscale {<major> {<minor>}}
         show tics

 If <minor> is not specified, it is 0.5*<major>.  The default size is 1.0 for
 major tics and 0.5 for minor tics.  Note that it is possible to have the tic
 marks pointing outward by specifying a negative size.
3 time
?set time
?show time
?time
 The optional `set time` places the time and date of the plot either at the
 top or bottom of the left margin.  The exact location is device dependent.

 Syntax:
         set time {<xoff>}{,<yoff>}
         set notime
         show time

 Specifying constants <xoff> or <yoff> as optional offsets for the time will
 move the time <xoff> or <yoff> character-screen co-ordinates.  For example,

         set time ,-3

 will change only the y offset of the time, moving the title down by roughly
 the height of three characters.
3 timefmt
?set timefmt
?show timefmt
?timefmt
 This command applies to timeseries where data are composed of dates/times.
 It has no meaning unless the command `set {x,y,z}data time` is given also.
 The string argument tells `gnuplot` how to read timedata from the datafile.
 Valid conversion codes are: %d (day of month,1--31), %m (month,1--12), %y
 (year,0--99), %Y (year, 4 digits), %j (day of year,1--365), %H (hour,0--24),
 %M (minute,0--60), %S (second,0--60).  Any character is allowed in the string
 (including space), but must match exactly.  Backslash-octals (\nnn) are
 converted to char; \t (tab) is understood.  If there is no separating
 character between the date/time elements, then %d, %m, %y, %H, %M and %S read
 two digits each, %Y reads four digits and %j reads three digits.  Each column
 in the timedata counts as one column in the `using n:n` specification.

 Syntax:
         set timefmt "<format string>"
         show timefmt

 See also `set {x,y,z}data`.

 Example:
         set timefmt "%d/%m/%Y\t%H:%M"
 tells `gnuplot` to read date and time separated by tab.
^ <a href=timedat/timedat.html> Time Data Demo </a>
3 title
?set title
?show title
?title
 The `set title` command produces a plot title that is centered at the top of
 the plot.  `set title` is a special case of `set label`.

 Syntax:
          set title {"<title-text>"} {<xoff>}{,<yoff>}
          show title

 Specifying constants <xoff> or <yoff> as optional offsets for the title will
 move the title <xoff> or <yoff> character screen co-ordinates (not plot
 co-ordinates).  For example,

          set title ,-1

 will change only the y offset of the title, moving the title down by
 roughly the height of one character.

 `set title` with no parameters clears the title.

 See `set syntax` for details about the processing of backslash sequences and
 the distinction between single- and double-quotes.
3 tmargin
 The command `set tmargin` sets the size of the top margin.  Please see
 `set margins` for details.
3 trange
 The `set trange` command sets the parametric range used to compute x and y
 values when in parametric or polar modes.  Please see `set range` for
 details.
3 urange
 The `set urange` and `set vrange` commands set the parametric ranges used
 to compute x, y, and z values when in `splot` parametric mode.  Please see
 `set range` for details.
3 variables
?show variables
 The `show variables` command lists all user-defined variables and their
 values.

 Syntax:
         show variables
3 view
?set view
?show view
?view
 The `set view` command sets the viewing angle for `splot`s.  It controls how
 the 3-d co-ordinates of the plot are mapped into the 2-d screen space.  It
 provides controls for both rotation and scaling of the plotted data, but
 supports orthographic projections only.

 Syntax:
         set view <rot_x> {,{<rot_z>}{,{<scale>}{,<scale_z>}}}
         show view

 where <rot_x> and <rot_z> control the rotation angles (in degrees) along a
 virtual 3-d co-ordinate system aligned with the screen such that the screen
 horizontal axis is x, screen vertical axis is y, and the axis perpendicular
 to the screen is z.  <rot_x> is bounded to the [0:180] range with a default
 of 60 degrees, while <rot_z> is bounded to the [0:360] range with a default
 of 30 degrees.  <scale> controls the scaling of the entire `splot`, while
 <scale_z> scales the z axis only.  Both scales default to 1.0.

 Examples:
         set view 60, 30, 1, 1
         set view ,,0.5

 The first sets all the four default values.  The second changes only scale,
 to 0.5.

 See also `set ticslevel`.
3 vrange
 The `set urange` and `set vrange` commands set the parametric ranges used
 to compute x, y, and z values when in `splot` parametric mode.  Please see
 `set range` for details.
3 x2data
 Sets x2-axis data to timeseries (dates/times).  Please see `set xdata`.
3 x2dtics
 The `set x2dtics` command changes tics on the x2 axis to days of the week.
 Please see `set xmtics` for details.
3 x2label
 This command sets the label for the x2 axis.  Please see `set xlabel`.
3 x2mtics
 The `set x2mtics` command changes tics on the x2 axis to months of the year.
 Please see `set xmtics` for details.
3 x2range
 The `set x2range` command sets the horizontal range that will be displayed
 on the x2 (top) axis.  Please see `set range` for details.
3 x2tics
 The `set x2tics` command controls major (labelled) tics on the x2 axis.
 Please see `set xtics` for details.
3 x2zeroaxis
 The `set x2zeroaxis` command draws a line at x2 = 0.  For details, please see
 `set zeroaxis`.
3 xdata
?set xdata
?show xdata
?xdata
 This command sets the datatype on the x axis to date/time.  A similar command
 does the same thing for each of the other axes.

 Syntax:
         set xdata time
         set ydata time
         set zdata time
         set x2data time
         set y2data time

 To turn the x axis data back to the default:
         set xdata

 See `set timefmt` to tell `gnuplot` how to read date or time data.  The
 date/time is converted to seconds from start of the century.  There is
 currently only one timefmt, which implies that all the date/time columns must
 confirm to this format.  Specification of ranges should be supplied as quoted
 strings according to this format to avoid interpretation of the date/time as
 an expression.

 The function "strftime" (type "man strftime" on unix to look it up) is used
 to print ticmark labels.  `gnuplot` tries to figure out a reasonable format
 for this  unless the `set format x "string"` has supplied something that does
 not look like a decimal format (more than one '%' or neither %f nor %g).
3 xdtics
?set xdtics
?set noxdtics
?show xdtics
?xdtics
?noxdtics
?set ydtics
?set noydtics
?show ydtics
?ydtics
?noydtics
?set zdtics
?set nozdtics
?show zdtics
?zdtics
?nozdtics
?set x2dtics
?set nox2dtics
?show x2dtics
?x2dtics
?nox2dtics
?set y2dtics
?set noy2dtics
?show y2dtics
?y2dtics
?noy2dtics
 The `set xdtics` commands converts the x-axis tic marks to days of the week
 where 0=Sun and 6=Sat.  Overflows are converted modulo 7 to dates.  `set
 noxdtics` returns the labels to their default values.  Similar commands do
 the same things for the other axes.

 Syntax:
        set xdtics
        set ydtics
        set zdtics
        set x2dtics
        set y2dtics
        set noxdtics
        etc.
        show xdtics
        etc.

 See also the `set format` command.
3 xlabel
?set xlabel
?show xlabel
?xlabel
?set ylabel
?show ylabel
?ylabel
?set zlabel
?show zlabel
?zlabel
?set x2label
?show x2label
?x2label
?set y2label
?show y2label
?y2label
 The `set xlabel` command sets the x axis label.  Similar commands set labels
 on the other axes.  There is no explicit `set x2label` command---use `set
 title` (see below).

 Syntax:
          set xlabel {"<label>"} {<xoff>}{,<yoff>}
          set ylabel {"<label>"} {<xoff>}{,<yoff>}
          set zlabel {"<label>"} {<xoff>}{,<yoff>}
          set y2label {"<label>"} {<xoff>}{,<yoff>}
          show xlabel
          etc.

 Specifying the constants <xoff> or <yoff> as optional offsets for a label
 will move it <xoff> or <yoff> character screen co-ordinates.  For example,

          set xlabel -1

 will change only the x offset of the xlabel, moving the label roughly one
 character width to the left.

 To clear the label, put no options on the command line.  For example,

          set y2label

 The default positions of the axis labels are as follows:

 xlabel:  The x-axis label is centered below the bottom axis.

 ylabel:  The position of the y-axis label depends on the terminal, and can be
 one of the following three positions:

 1. Horizontal text flushed left at the top left of the plot.  Terminals that
 cannot rotate text will probably use this method.

 2. Vertical text centered vertically at the left of the plot.  Terminals that
 can rotate text will probably use this method.

 3. Horizontal text centered vertically at the left of the plot.  The EEPIC,
 LaTeX and TPIC drivers use this method.  The user must insert line breaks
 using \\ to prevent the ylabel from overwriting the plot.  To produce a
 vertical row of characters, add \\ between every printing character (but this
 is ugly).

 zlabel: The z-axis label is centered along the z axis and placed in the space
 above the grid level.

 y2label: The y2-axis label is placed to the right of the y2 axis.  The
 position is terminal-dependent in the same manner as is the y-axis label.

 x2label: There is no `set x2label` command.  If you want to put a label on
 the x2 axis, use the 'set title' command with new-line characters "\n", i.e.,

          set title "This is the title\n\nThis is the x2label"

 Note that double quotes must be used.

 Please see `set syntax` for further information about backslash processing
 and the difference between single- and double-quoted strings.
3 xmtics
?set xmtics
?set noxmtics
?show xmtics
?xmtics
?noxmtics
?set ymtics
?set noymtics
?show ymtics
?ymtics
?noymtics
?set zmtics
?set nozmtics
?show zmtics
?zmtics
?nozmtics
?set x2mtics
?set nox2mtics
?show x2mtics
?x2mtics
?nox2mtics
?set y2mtics
?set noy2mtics
?show y2mtics
?y2mtics
?noy2mtics
 The `set xmtics` commands converts the x-axis tic marks to months of the
 year where 1=Jan and 12=Dec.  Overflows are converted modulo 12 to months.
 The tics are returned to their default labels by `set noxmtics`.  Similar
 commands perform the same duties for the other axes.

 Examples:
        set xmtics
        set ymtics
        set zmtics
        set x2mtics
        set y2mtics
        set noxmtics
        etc.
        show xmtics
        etc.

 See also the `set format` command.
3 xrange
 The `set xrange` command sets the horizontal range that will be displayed
 on the x axis.  Please see `set range` for details.
3 xtics
?set xtics
?set noxtics
?show xtics
?xtics
?noxtics
?set ytics
?set noytics
?show ytics
?ytics
?noytics
?set ztics
?set noztics
?show ztics
?ztics
?noztics
?set x2tics
?set nox2tics
?show x2tics
?x2tics
?nox2tics
?set y2tics
?set noy2tics
?show y2tics
?y2tics
?noy2tics
 Fine control of the major (labelled) tics on the x axis is possible with the
 `set xtics` command.  The tics may be turned off with the `set noxtics`
 command, and may be turned on (the default state) with `set xtics`.  Similar
 commands control the major tics on the other axes.

 Syntax:
          set xtics {axis | border} {{no}mirror} \
                      { {<start>, <incr>{, <end>}} |
                      {({"<label>"} <pos> {, {"<label>"} <pos>}...)} }
          set ytics (same options)
          set ztics (same options)
          set x2tics (same options)
          set y2tics (same options)
          set noxtics
          etc.
          show xtics
          etc.

 `axis` or `border` tells `gnuplot` to put the tics (both the tics themselves
 and the accompanying labels) along the axis or the border, respectively.
 `mirror` tells it to put unlabelled tics at the same positions on the
 opposite border.  `nomirror` does what you think it does.  The defaults are
 `border mirror` for tics on the x, y, x2, and y2 axes.  For the z axis, the
 the `{axis|border}` option is not available and the default is `nomirror`.
 If you do want to mirror the z-axis tics, you might want to create a bit more
 room for them with `set border`.

 The positions of the tics may be specified in either of two forms:

 The <start>, <incr>, <end> form specifies that a series of tics will be
 plotted on the axis between the values <start> and <end> with an increment of
 <incr>.  If <end> is not given, it is assumed to be infinity.  The increment
 may be negative.

 Example:
           set xtics 0,.5,10
 makes tics at 0, 0.5, 1, 1.5, ..., 9.5, 10.

 The ("<label>" <pos>, ...) form allows arbitrary tic positions or non-numeric
 tic labels.  A set of tics is a set of positions, each with its own optional
 label.  Note that the label is a string enclosed by quotes, and may be a
 constant string, such as "hello", or contain formatting information for the
 tic number (which is the same as the position), such as "%3f clients".  See
 `set format` for more information about this case.  The label may be made
 empty by specifying it as an empty string.  If no string is given, the
 default label (numerical) is used.  In this form, the tics do not need to be
 listed in numerical order.

 Examples:
          set xtics ("low" 0, "medium" 50, "high" 100)
          set xtics (1,2,4,8,16,32,64,128,256,512,1024)
          set ytics ("bottom" 0, "" 10, "top" 20)

 In the second example, all tics are labelled.  In the third, only the end
 tics are labelled.

 Tics will only be plotted when in range.

 Minor (unlabelled) tics can be added by the `set mxtics` command.

 In case of timeseries data, position values must be given as quoted dates
 or times according to the format `timefmt`.
3 xzeroaxis
 The `set xzeroaxis` command draws a line at x = 0.  For details, please see
 `set zeroaxis`.
3 y2data
 Sets y2-axis data to timeseries (dates/times).  Please see `set xdata`.
3 y2dtics
 The `set y2dtics` command changes tics on the y2 axis to days of the week.
 Please see `set xmtics` for details.
3 y2label
 This command sets the label for the y2 axis.  Please see `set xlabel`.
3 y2mtics
 The `set y2mtics` command changes tics on the y2 axis to months of the year.
 Please see `set xmtics` for details.
3 y2range
 The `set y2range` command sets the vertical range that will be displayed on
 the y2 axis.  Please see `set range` for details.
3 y2tics
 The `set y2tics` command controls major (labelled) tics on the y2 axis.
 Please see `set xtics` for details.
3 y2zeroaxis
 The `set y2zeroaxis` command draws a line at y2 = 0.  For details, please see
 `set zeroaxis`.
3 ydata
 Sets y-axis data to timeseries (dates/times).  Please see `set xdata`.
3 ydtics
 The `set ydtics` command changes tics on the y axis to days of the week.
 Please see `set xmtics` for details.
3 ylabel
 This command sets the label for the y axis.  Please see `set xlabel`.
3 ymtics
 The `set ymtics` command changes tics on the y axis to months of the year.
 Please see `set xmtics` for details.
3 yrange
 The `set yrange` command sets the vertical range that will be displayed on
 the y axis.  Please see `set range` for details.
3 ytics
 The `set ytics` command controls major (labelled) tics on the y axis.
 Please see `set xtics` for details.
3 yzeroaxis
 The `set yzeroaxis` command draws a line at y = 0.  For details, please see
 `set zeroaxis`.
3 zdata
 Set zaxis date to timeseries (dates/times).  Please see `set xdata`.
3 zdtics
 The `set zdtics` command changes tics on the z axis to days of the week.
 Please see `set xmtics` for details.
3 zero
?set zero
?show zero
?zero
 The `zero` value is the default threshold for values approaching 0.0.

 Syntax:
         set zero <expression>
         show zero

 `gnuplot` will not plot a point if its imaginary part is greater in magnitude
 than the `zero` threshold.  Axis ranges cannot be less than `zero`.  The
 default `zero` value is 1e-8.
3 zeroaxis
?set zeroaxis
?set nozeroaxis
?show zeroaxis
?zeroaxis
?nozeroaxis
?set xzeroaxis
?set noxzeroaxis
?show xzeroaxis
?xzeroaxis
?noxzeroaxis
?set yzeroaxis
?set noyzeroaxis
?show yzeroaxis
?yzeroaxis
?noyzeroaxis
?set x2zeroaxis
?set nox2zeroaxis
?show x2zeroaxis
?x2zeroaxis
?nox2zeroaxis
?set y2zeroaxis
?set noy2zeroaxis
?show y2zeroaxis
?y2zeroaxis
?noy2zeroaxis
 The command `set zeroaxis` draws the x axis and y axis.  It may be removed by
 `set nozeroaxis`.  The x axis alone may be drawn by `set xzeroaxis` and
 removed by `set noxzeroaxis`.  Similar commands behave similarly for the y,
 x2, and y2 axes.

 Syntax:
         set zeroaxis {<linestyle>}
         set xzeroaxis {<linestyle>}
         set yzeroaxis {<linestyle>}
         set x2zeroaxis {<linestyle>}
         set y2zeroaxis {<linestyle>}
         set nozeroaxis
         set noxzeroaxis
         etc.
         show zeroaxis
         show xzeroaxis
         etc.

 By default, these options are off.  If <linestyle> is not specified, any
 zero axes selected will be drawn using the axis linetype.

 `set zeroaxis l` is equivalent to `set xzeroaxis l; set yzeroaxis l`.
 `set nozeroaxis` is equivalent to `set noxzeroaxis; set noyzeroaxis`.
3 zlabel
 This command sets the label for the z axis.  Please see `set xlabel`.
3 zmtics
 The `set zmtics` command changes tics on the z axis to months of the year.
 Please see `set xmtics` for details.
3 zrange
 The `set zrange` command sets the range that will be displayed on the z axis.
 The zrange is used only by `splot` and is ignored by `plot`.  Please see `set
 range` for details.
3 ztics
?set ztics
 The `set ztics` command controls major (labelled) tics on the z axis.
 Please see `set xtics` for details.
2 shell
?shell
 The `shell` command spawns an interactive shell.  To return to `gnuplot`,
 type `logout` if using VMS, `exit` or the END-OF-FILE character if using
 Unix, `endcli` if using AmigaDOS, or `exit` if using MS-DOS or OS/2.

 A single shell command may be spawned by preceding it with the ! character
 ($ if using VMS) at the beginning of a command line.  Control will return
 immediately to `gnuplot` after this command is executed.  For example, in
 Unix, AmigaDOS, MS-DOS or OS/2,

      ! dir

 prints a directory listing and then returns to `gnuplot`.

 On an Atari, the `!` command first checks whether a shell is already loaded
 and uses it, if available.  This is practical if `gnuplot` is run from
 `gulam`, for example.
2 splot
?splot
?surface plot
 Three-dimensional surface and contour plotting is available in `gnuplot` with
 the `splot` command.  See the `plot` command for features common to the
 `plot` command.

 See also `set contour`, `set cntrparam`, and `set surface`.
^ <a href=surfacea/surfacea.html>Non parametric Splot Demos</a>
^ <a href=surfaceb/surfaceb.html>Parametric Splot Demos.</a>
2 start-up
?startup
?start
?.gnuplot
 When `gnuplot` is run, it looks for an initialization file to load.  This
 file is called `.gnuplot` on Unix and AmigaDOS systems, and `GNUPLOT.INI`
 on other systems.  If this file is not found in the current directory, the
 program will look for it in the home directory (under AmigaDOS,
 Atari(single)TOS, MS-DOS and OS/2, the environment variable `gnuplot` should
 contain the name of this directory).  Note: if NOCWDRC is defined during the
 installation, `gnuplot` will not read from the current directory.

 If this file is found, `gnuplot` executes the commands in this file.  This
 is most useful for setting the terminal type and defining any functions or
 variables that are used often.
2 substitution
?substitution
 Command-line substitution is specified by a system command enclosed in
 backquotes.  This command is spawned and the output it produces replaces
 the name of the command (and backquotes) on the command line.

 Newlines in the output produced by the spawned command are replaced with
 blanks.

 Command-line substitution can be used anywhere on the `gnuplot` command
 line.

 Example:

 This will run the program `leastsq` and replace `leastsq` (including
 backquotes) on the command line with its output:

          f(x) = `leastsq`

 or, in VMS

          f(x) = `run leastsq`
2 syntax
?syntax
?specify
?punctuation
 The general rules of syntax and punctuation in `gnuplot` are that keywords
 and options are order-dependent.  Options and any accompanying parameters are
 separated by spaces whereas lists and co-ordinates are separated by commas.
 Ranges are separated by colons and enclosed in braces [], text and file names
 are enclosed in quotes, and a few miscellaneous things are enclosed in
 parentheses.  Brackets {} are used for a few special purposes.

 Commas are used to separate co-ordinates (see `set co-ordinates`); the list
 of variables being fitted (the list after the `via` keyword on the `fit`
 command); lists of discrete contours or the loop parameters which specify
 them (see `set cntrparam`); the arguments of the `set` commands `dgrid3d`,
 `dummy`, `isosamples`, `offsets`, `origin`, `samples`, `size`, `time`, and
 `view`; lists of tics or the loop parameters which specify them; the offsets
 for titles and axis labels; parametric functions to be used to calculate the
 x, y, and z co-ordinates on the `s/plot` commands; and the complete sets of
 keywords specifying individual data sets or functions on `s/plot` commands.

 Parentheses are used to delimit sets of explicit tics (as opposed to loop
 parameters) and to indicate computations in the `using` filter of the `fit`
 and `s/plot` commands.

 (Parentheses and commas are also used as usual in function notation.)

 Braces are used to delimit ranges, whether they are given in `set` commands
 or on `s/plot` commands.

 Colons are used to separate extrema in `range` specifications and to
 separate columns in the `using` filter of the `s/plot` and `fit` commands.

 Semicolons are used to separate commands given on a single line.

 Brackets are used in text to be specially processed by some terminals, like
 `enhpost`.  They are also used to denote complex numbers: {3,2} = 3 + 2i.

 Text may be enclosed in single- or double-quotes.  Backslash processing of
 sequences like \n (newline) is performed for double-quoted strings, but not
 for single-quoted strings.  The justification is the same for each line of a
 multi-line string.  Thus the center-justified string

        "This is the first line of text.\nThis is the second line."

 will produce

         This is the first line of text.
            This is the second line.

 but

        'This is the first line of text.\nThis is the second line.'

 will produce

         This is the first line of text.\nThis is the second line.

 Both single- and double-quoted strings process \nnn correctly.

 The EEPIC, Imagen, Uniplex, LaTeX, and TPIC drivers allow \\ in a string to
 specify a newline.
2 test
?test
 `test` creates a display of line and point styles and other useful things
 appropriate for the terminal you are using.

 Syntax: test
2 update
?update
 This command updates the start parameter assignments in a start parameter
 file as specified in the `fit` section.  Each parameter will be replaced
 by its actual value.  This is useful for restarting a converged or stopped
 fit again.

 Syntax:
         update <filename>

 See `fit`
2 user-defined
?userdefined
?variables
 New user-defined variables and functions of one through five variables may
 be declared and used anywhere.

 User-defined function syntax:
         <function-name> ( <dummy1> {,<dummy2> {, ...} } ) = <expression>

 where <expression> is defined in terms of <dummy1> through <dummy5>.

 User-defined variable syntax:
         <variable-name> = <constant-expression>

 Examples:
         w = 2
         q = floor(tan(pi/2 - 0.1))
         f(x) = sin(w*x)
         sinc(x) = sin(pi*x)/(pi*x)
         delta(t) = (t == 0)
         ramp(t) = (t > 0) ? t : 0
         min(a,b) = (a < b) ? a : b
         comb(n,k) = n!/(k!*(n-k)!)
         len3d(x,y,z) = sqrt(x*x+y*y+z*z)

 Note that the variable `pi` is already defined.

 See `show functions` and `show variables`.
2 bugs
?bugs
 The bessel functions do not work for complex arguments.

 The gamma function does not work for complex arguments.

 There is a bug in the stdio library for old Sun operating systems (SunOS
 Sys4-3.2).  The "%g" format for 'printf' sometimes incorrectly prints numbers
 (e.g., 200000.0 as "2").  Thus, tic mark labels may be incorrect on a Sun4
 version of `gnuplot`.  A work-around is to rescale the data or use the `set
 format` command to change the tic mark format to "%7.0f" or some other
 appropriate format.  This appears to have been fixed in SunOS 4.0.

 Another bug: On a Sun3 under SunOS 4.0, and on Sun4's under Sys4-3.2 and
 SunOS 4.0, the 'sscanf' routine incorrectly parses "00 12" with the format
 "%f %f" and reads 0 and 0 instead of 0 and 12.  This affects data input.  If
 the data file contains x co-ordinates that are zero but are specified like
 '00', '000', etc, then you will read the wrong y values.  Check any data
 files or upgrade the SunOS.  It appears to have been fixed in SunOS 4.1.1.

 Suns appear to overflow when calculating exp(-x) for large x, so `gnuplot`
 gets an undefined result.  One work-around is to make a user-defined function
 like e(x) = x<-500 ? 0 : exp(x).  This affects plots of Gaussians (exp(-x*x))
 in particular, since x*x grows quite rapidly.

 Microsoft C 5.1 has a nasty bug associated with the %g format for printf.
 When any of the formats "%.2g", "%.1g", "%.0g", "%.g" are used, printf will
 incorrectly print numbers in the range 1e-4 to 1e-1.  Numbers that should be
 printed in the %e format are incorrectly printed in the %f format, with the
 wrong number of zeros after the decimal point.  To work around this problem,
 use the %e or %f formats explicitly.

 `gnuplot`, when compiled with Microsoft C, did not work correctly on two VGA
 displays that were tested.  The CGA, EGA and VGA drivers should probably be
 rewritten to use the Microsoft C graphics library.  `gnuplot` compiled with
 Borland C++ uses the Turbo C graphics drivers and does work correctly with
 VGA displays.

 VAX/VMS 4.7 C compiler release 2.4 also has a poorly implemented %g format
 for printf.  The numbers are printed numerically correct, but may not be in
 the requested format.  The K&R second edition says that for the %g format, %e
 is used if the exponent is less than -4 or greater than or equal to the
 precision.  The VAX uses %e format if the exponent is less than -1.  The VAX
 appears to take no notice of the precision when deciding whether to use %e or
 %f for numbers less than 1.  To work around this problem, use the %e or %f
 formats explicitly.  From the VAX C 2.4 release notes: e,E,f,F,g,G  Result
 will always contain a decimal  point.  For g and G, trailing zeros will not
 be removed from the result.

 VAX/VMS 5.2 C compiler release 3.0 has a slightly better implemented %g
 format than release 2.4, but not much.  Trailing decimal points are now
 removed, but trailing zeros are still not removed from %g numbers in
 exponential format.

 ULTRIX X11R3 has a bug that causes the X11 driver to display "every other"
 plot.  The bug seems to be fixed in DEC's release of X11R4 so newer releases
 of ULTRIX don't seem to have the problem.  Solutions for older sites include
 upgrading the X11 libraries (from DEC or direct from MIT) or defining
 ULTRIX_KLUDGE when compiling the x11.trm file.  Note that the kludge is not
 an ideal fix, however.

 The constant HUGE was incorrectly defined in the NeXT OS 2.0 operating
 system.  HUGE should be set to 1e38 in plot.h. This error has been corrected
 in the 2.1 version of NeXT OS.

 Some older models of HP plotters do not have a page eject command 'PG'.  The
 current HPGL driver uses this command in HPGL_reset.  This may need to be
 removed for these plotters.  The current PCL5 driver uses HPGL/2 for text as
 well as graphics.  This should be modified to use scalable PCL fonts.

 On the Atari version, it is not possible to send output directly to the
 printer (using `/dev/lp` as output file), since CRs are added to LFs in
 binary output.  As a work-around, write the output to a file and copy it to
 the printer afterwards using a shell command.

 There may be an up-to-date list of bugs since the release on the WWW page:
    http://www.cs.dartmouth.edu/gnuplot

 Please report any bugs to [e-mail].